Bruge page-elements i en klasse

Hvordan ser den ud, den funktion der bruges til dit GridView?

Jeg har ikke lavet den endnu, da jeg ret hurtigt stødte på problemet. Men jeg forsøger at kalde et gridview, der hedder "gridview1".

Jeg udvikler i Visual Web Developer, og allerede der kan jeg se, at den ikke kan genkender gridview1. Det giver også fejl, når jeg førsøger at køre siden.

Kør gennem dataset til GW med de funktioner, som du ønsker at bruge fra class og databind dernæst til GW

:-) karsten_larsen

Jeg er bange for, at du tabte mig der :-) Jeg forstår ikke helt hvad du mener?!

Ved hvilken event skal myClass kaldes?

Jeg har f.eks. en .aspx side med et gridview og en knap. Ved klik på knappen skal myClass kaldes.

Jeg er blevet nødt til at lade knappen kalde en sub i min codebehind side, og så lade den sub kalde myClass. Subs i myClass kan ikke kaldes direkte fra .aspx siden (så fejler den ved at den ikke kan finde sub'en).

Du gør sådan her:

Du må af en eller anden grund ikke kalde din klasse myClass og bruge den som identifier, så jeg har kaldt den testClass i stedet og smidt den i mappen AppCode.
Hvis du bruger SQLServer så skal du skifte til System.Data.Sql i stedet for OleDB,
som her i eksemplet hvor det er en Access.

TestClass.vb (husk at rette ConnectionString til den du har konf. i web.config)

Imports Microsoft.VisualBasic
Imports System.Data
Imports System.Data.OleDb

Public Class testClass
    Function GetData(ByVal queryString As String) As DataSet
        Dim connectionString As String = ConfigurationManager.ConnectionStrings("DinConnectionString").ConnectionString
        Dim ds As New DataSet()
        Try
            Dim connection As New OleDbConnection(connectionString)
            Dim adapter As New OleDbDataAdapter(queryString, connection)
            adapter.Fill(ds)
        Catch ex As Exception
            HttpContext.Current.Response.Write(ex.ToString())
            ' Lav noget fejl-lir her
        End Try
        Return ds
    End Function
End Class

Så en aspx-side der hedder test.aspx:

Her placerer du et GridView og kalder det GridView1

I denne sides codebehind, test.aspx.vb kalder du funktionen
der er defineret i testClass, og binder til dit GridView1 som
nævnt:

Imports System.Data

Partial Class test
    Inherits System.Web.UI.Page

    Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        If Not IsPostBack Then
            'Instantier din testClass her
            Dim t As New testClass

            Dim queryString As String = _
              "SELECT * FROM DinTabel"

            'Smid din sql-streng ind i din function i testClass
            'og Bind til det gridview du har på siden.
            Dim ds As DataSet = t.GetData(queryString)
            If (ds.Tables.Count > 0) Then
                GridView1.DataSource = ds
                GridView1.DataBind()
            Else
                Response.Write("Kan ikke connecte til db")
            End If
        End If
    End Sub
End Class

Så skulle det virke =)

Alternativt skal du smide GridView1 med ind i funktionen i testClass og binde den derinde fra, som du jo egentlig forespørger:

testClass.vb:

Imports Microsoft.VisualBasic
Imports System.Data
Imports System.Data.OleDb

Public Class testClass
    Public Function GetData(ByVal queryString As String, ByVal g As GridView) As DataSet
        Dim connectionString As String = ConfigurationManager.ConnectionStrings("DinConnectionString").ConnectionString
        Dim ds As New DataSet()
        Try
            Dim connection As New OleDbConnection(connectionString)
            Dim adapter As New OleDbDataAdapter(queryString, connection)
            adapter.Fill(ds)

            g.DataSource = ds
            g.DataBind()

        Catch ex As Exception
            HttpContext.Current.Response.Write(ex.ToString())
            ' Lav noget fejl-lir her
        End Try
        Return ds
    End Function
End Class

Og din codebehind test.aspx.vb:

Imports System.Data
Imports testClass

Partial Class test
    Inherits System.Web.UI.Page

    Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        If Not IsPostBack Then
            Dim t As New testClass
            Dim queryString As String = _
              "SELECT * FROM DinTabel"
            Dim ds As DataSet = t.GetData(queryString, GridView1)
        End If
    End Sub
End Class

Herved skal du jo skrive mindre kode når du skal kalde funktionen, men så kan du kun bruge klassen til at binde GridViews, hvilket gør den mindre fleksibel... Jeg hælder mest til første løsning.

Perfekt, torotune! Det sidste forslag passer til mit formål, så nu kan jeg få fat på mit gridview. Tak for hjælpen, og opretter du et svar?!

Det var så lidt, og godt det virker!

Men ja, så skal du smide GridView1 med ind som parameter, men så er funktionen også låst til kun at kunne behandle GridViews. - Det kunne jo være du skulle bruge nogle af de andre datakontroller. Men så kan du selvfølgelig bare have begge funktioner i din klasse. Up 2 u =)