Hvad er galt med dette program

Du mangler en "end if":

        Unload HovedMenu
        End With
        End If
End Sub

..tror jeg.. :-)

Men er det ikke nemmere at bruge Select Case..?

næh.. det er det vist ikke, da det er ikke samme objekt, der har forskellige værdier, men forskellige objekter der har samme værdi.. :-)

Et godt råd, toh:

Lav indrykninger ved It-then, loops m.m.:
Derved opdager man, at du også mangler 3 End With:

Private Sub cmdOK_Click()
    If Option1.Value = True Then
        Set ObjW = CreateObject("word.application")
        With ObjW
            .Visible = True
            .Documents.Add ("D:\flc_Menu\flc-standard.dot"), False
            .Activate
        End With
    ElseIf Option2.Value = True Then
        Set ObjW = CreateObject("word.application")
        With ObjW
            .Visible = True
            .Documents.Add ("D:\flc_Menu\FLC-Faxskrivelse.dot"), False
            .Activate
            Unload HovedMenu
        End With
    ElseIf Option3.Value = True Then
        Set ObjW = CreateObject("word.application")
        With ObjW
            .Visible = True
            .Documents.Add ("D:\flc_Menu\FLC-Flgskrivelse.dot"), False
            .Activate
            Unload HovedMenu
        End With
    ElseIf Option4.Value = True Then
        Set ObjW = CreateObject("word.application")
        With ObjW
            .Visible = True
            .Documents.Add ("D:\flc_Menu\FLC-Nord RekvireringAfSager.dot"), False
            .Activate
            Unload HovedMenu
        End With
    End if
End Sub

hm... man kunne vel også vende den om, og sige at der er for mange "with"..

Dette burde også virke:

        Set ObjW = CreateObject("word.application")
        With ObjW

        if ... then...
        elseif..

        end with

ja, du har ret! Og du har også ret i at en Select Case vil være kønnere:
Private Sub cmdOK_Click()
    Set ObjW = CreateObject("word.application")
    With ObjW
        Select Case True
            case Option1.Value
                .Visible = True
                .Documents.Add ("D:\flc_Menu\flc-standard.dot"), False
                .Activate
            case Option2.Value
                .Visible = True
                .Documents.Add ("D:\flc_Menu\FLC-Faxskrivelse.dot"), False
                .Activate
                Unload HovedMenu
            case Option3.Value
                .Visible = True
                .Documents.Add ("D:\flc_Menu\FLC-Flgskrivelse.dot"), False
                .Activate
                Unload HovedMenu
            case Option4.Value
                .Visible = True
                .Documents.Add ("D:\flc_Menu\FLC-Nord RekvireringAfSager.dot"), False
                .Activate
                Unload HovedMenu
        End Select
    End With
End Sub

Ahh.. den omvendte.. :-)

        Select Case True
            case Option1.Value

Nu går der sport i, at korte koden ned:

Private Sub cmdOK_Click()
    Set ObjW = CreateObject("word.application")
    With ObjW
        .Visible = True
        Select Case True
            case Option1.Value
                .Documents.Add ("D:\flc_Menu\flc-standard.dot"), False
            case Option2.Value
                .Documents.Add ("D:\flc_Menu\FLC-Faxskrivelse.dot"), False
            case Option3.Value
                .Documents.Add ("D:\flc_Menu\FLC-Flgskrivelse.dot"), False
          case Option4.Value
                .Documents.Add ("D:\flc_Menu\FLC-Nord RekvireringAfSager.dot"), False
        End Select
        .Activate
        Unload HovedMenu
    End With
End Sub

thesurfer->ja, den 'omvendte' er ret genial i mange henseender :o)

..og hvis filerne bruges en del, kan strengene med fordel erstattes af variabler:

option explicit ' dette er helt oppe i vb programmet
dim flc_std, flc_fax, flc_flg, flc_nrdrek ' også denne her


' selve sub'en eller *form_load*:
flc_std = "D:\flc_Menu\flc-standard.dot"
flc_fax = "D:\flc_Menu\FLC-Faxskrivelse.dot"
flc_flg = "D:\flc_Menu\FLC-Flgskrivelse.dot"
flc_nrdrek = "D:\flc_Menu\FLC-Nord RekvireringAfSager.dot"

        Select Case True
            case Option1.Value
                .Documents.Add (flc_std), False
            case Option2.Value
                .Documents.Add (flc_fax), False
            case Option3.Value
                .Documents.Add (flc_flg), False
          case Option4.Value
                .Documents.Add (flc_nrdrek), False
        End Select

De her kan så bruges senere, når man vil ha' fat i filerne: flc_std, flc_fax, flc_flg, flc_nrdrek

mange ting kan forkortes.. :-)

Måske kan vi få koden kortet ned til ét ord....og dog ;o)

how about taking a look at this question toh, I see your using some of the code here :o)
http://www.eksperten.dk/spm/504838

Du har ret Terry jeg glemte at gentage "End With" som du hjalp mig med i går

You need to close the previous question too :o)