VBA - Excelberegninger fra Word

Jo - der kan oprettes et Excel-objekt, der kan forsynes med data, formler m.v. via VBA - resultater kan returneres til Word.

Det er så også det jeg har gjort og det virker i bund og grund perfekt, men det er samtidig lidt tungt, da jeg åbner og lukker Excel flere gange.
Jeg tænkte mere hen i retning af, om der evt. fantes en slags beregningsmotor, som jeg blot kunne sætte en reference til og dermed havde en "Excel Light"?

Prøv evt. at vis den kode, som du har anvendt.

Dette er koden jeg benytter mig af.
Når brugeren har dannet sit brev - og i den forbindelse kaldt "Calculate" med en formel - vil jeg jo gerne rydde op, og lukker derfor pænt Excel igen.
Næste gang der så skal laves et brev, skal jeg så åbne Excel på ny - og det er den process der virker lidt tung.
Men jeg er heller ikke meget for, blot at lade Excel være Excel og ikke rydde op - eller er manuel oprydning bare et levn fra gamle dage? :-)

Function Calculate(ByVal sFormular As String) As Double
On Error GoTo Calculate_ERROR

  Xls.Cells(1, 1).Formula = "=" & sFormular
 
  Calculate = Xls.Cells(1, 1).Value

  Exit Function

Calculate_ERROR:

  Select Case Err.Number
    Case ERR_LEAVE_PROGRAM
      Err.Raise ERR_LEAVE_PROGRAM
    Case Else
      ShowMessageBox 1210, sFormular
      Err.Raise ERR_CALC_ERROR
  End Select

End Function


Function Xls() As Excel.Worksheet
On Error GoTo Xls_ERROR

  If oWkSheet Is Nothing Then
    Set oExcel = GetObject(, "Excel.Application")
    Set oWkBook = oExcel.Workbooks.Add
    Set oWkSheet = oWkBook.ActiveSheet
  End If
 
  Set Xls = oWkSheet
 
  Exit Function
 
Xls_ERROR:

  Select Case Err.Number
    Case 429
      Set oExcel = CreateObject("Excel.Application")
      Resume Next
    Case Else
      ShowMessageBox 1220, Err.Number, Err.Description
      Err.Raise ERR_LEAVE_PROGRAM
  End Select

End Function

Hvor komplekse er beregningerne, som udføres i Excel?

Beregningerne vil typisk være nogle procentberegninger, beregning af gebyr samt ned- og oprundinger af beløb, før videre beregning.
Beregninger jeg tidligere har hardcodet i VBA, men da den slags beregninger altid ændre sig, så vil jeg nu lægge det ud til superbrugerne.
De skal så selv danne formlerne, som derefter kan bruges til pensionsberegninger i Wordbreve.
For at teste syntaksen i formlerne, og senere beregne dem rigtig, smider jeg dem lige over i Excel og hiver resultatet tilbage.
Der findes godt nok en selection.calculate i Word, men den kan ikke dække behovet.

Hvis du i Word laver reference til Microsoft Excel xx.x Object library, skulle koden kunne bruges.

Laver en tekstboks og en  kommandoknap i word, kan denne måske bruges, formlen skrives i tekstboksen og resultatet kommer tilbege der.

Denne i et modul
Function Calculate(ByVal sFormular As String) As Double
    On Error GoTo Calculate_ERROR
    Calculate = Evaluate(sFormular)
    Exit Function

Calculate_ERROR:

    Select Case Err.Number
    Case ERR_LEAVE_PROGRAM
        Err.Raise ERR_LEAVE_PROGRAM
    Case Else
        MsgBox sFormular
        Err.Raise ERR_CALC_ERROR
    End Select

End Function


og denne  under kommandoknappen

Private Sub CommandButton1_Click()
TextBox1 = Calculate(TextBox1)
End Sub

Du kan måske lave den så kort her

Private Sub CommandButton1_Click()
TextBox1 = Evaluate(TextBox1)
End Sub