Endnu et objekt problem - kald af handlers

Der er forskel i kald for sprites og objekter(parent scripts)

------------- Parent script "SpriteMover"-----------------
property pSprite

-- Her opretter du objektet med et parameter som er sprite kanalen:
on new me, spr
me.pSprite = sprite(spr)
return me
end

-- Her er en handler til at flytte den sprite der er knyttet til objektet
on moveSprite me, amount
me.pSprite.locH = me.pSprite.locH + amount
end

-- her et eksempel på en handler der returnerer
on getSpriteRef me
return me.pSprite
end

----------------------------------
Du gemmer typisk dit objekt i en global variabel. Du opretter objektet udfra ovenstående parent script sådan her:

global gMitObjekt
gMitObjekt = new script("SpriteMover", 4)
-- 4 er spritekanalen

For at flytte sprite'n:
gMitObjekt.moveSprite(5)

put gMitObjekt.getSpriteRef()

---------------------- Behaviors er stort set det samme, bortset far at de placere direkte på sprite'n:

property pSprite

on beginSprite me
me.pSprite = sprite(me.spriteNum)
end

-- Her er en handler til at flytte sprite
on moveSprite me, amount
me.pSprite.locH = me.pSprite.locH + amount
end

-- her et eksempel på en handler der returnerer
on getSpriteRef me
return me.pSprite
end


Behaviors behøver ikke decideret et initialiserings kald som parent scripts, da de bliver trigge't ved første frame gennemgang(beginSprite). Her spørger den direkte, "hvilken sprite er knytte til mig?"

Du kalder på en af to måder.

sprite(4).moveSprite(5) eller
sendSprite(4, #moveSprite, 5)

Gæt hvad sendAllSprites(#moveSprite, 5) gør !! ;-)

Jeg har ikke testet det i Director, så der kan være taste fejl...

- Kanding

Hmm, ok. Jeg er vist stadig for java skadet til at Lingo bare er ligetil. Men det kommer nok lidt efter lidt. Jeg kunne hvertfald bruge svaret, så tak for det :)