Sende mail fra Access

Du akn sagtens sende e-mail fra Access, men om du kan gøre det til andre mailsystemer end Outlook / outlook expres er jeg ikke klar over. Jeg har ikke Access på denne maskine, og kan således ikke afprøve det.

Prøv at lave en makro og eksperimenter med kommandoen SendObject. Jeg plejer at benytte flg:

DoCmd.SendObject,"","","mugs@mail.dk", "", "" "Emne","Dette er en prøve",False,""

først åpner du din database....

Session("FromName") = Request("FromName")
Session("FromAddress") = Request("FromAddress")
Session("Subject") = Request("Subject")
Session("BodyText") = Request("BodyText")

Set Mailer = Server.CreateObject("sett in server")

    'Sette variabler
    Mailer.FromName = Session("FromName")
    Mailer.FromAddress = Session("FromAddress")
    Mailer.RemoteHost = "smtpgw.activeisp.com"
    Mailer.AddRecipient "Fra web: ", " "& RS("Email")&" "
    Mailer.Subject = Session("Subject")
    Mailer.BodyText = Session("BodyText")

'Sjekker om mail er sendt, hvis ikke vises en feilmelding
if Mailer.SendMail then
Response.Write "Mailen er sendt!"
else
Response.Write "Mail send failure. Error was " & Mailer.Response
end if

'Avsutter session variabelen
Session.Abandon

så lukker du din database

Hej igen
Jeg kan godt lave makroen, og når jeg afspiller den, starter den også fint mailen op, men den tager ikke alle mine mailadresser med over, og det er jo netop det, som jeg har brug for.

Du kan sagtens markere alle mailadresser i en liste i Access, og sende via Access. Men nu har du jo accepteret et svar, og dermed er spørgsmålet jo lukket, da du naturligvis har afprøvet det afgivne svar inden du accepterede.

her er lidt du kan sammenligne din egen funktion med:

Public Function fhpSendEmail(strRecip As String, strSubject As String, strMsg As String, Optional strCC As String) As Boolean
' -----------------------------------------------------------------------------------
' Purpose      : Send an e-mail to an Outlook recipient
' Called from  :
' Returns      :
' Remarks      :
' -----------------------------------------------------------------------------------
On Error GoTo Error_fhpSendEmail
  Dim strInfoMsg As String                                      'Info message
  Dim objOutlook As Outlook.Application                        'Outlook variable
  Dim objOutlookMsg As Outlook.MailItem                        'Outlook variable
  Dim objOutlookRecip As Outlook.Recipient                      'Outlook variable
         
  If (strRecip <> "") And (strSubject <> "") And (strMsg <> "") Then
    Set objOutlook = CreateObject("Outlook.Application")        'Create the Outlook session
    Set objOutlookMsg = objOutlook.CreateItem(olMailItem)      'Create the message

    With objOutlookMsg                                          'The message
      Set objOutlookRecip = .Recipients.Add(strRecip)          'Recipient of the message
      objOutlookRecip.Type = olTo

      If strCC <> "" Then                                      'If CC recipients
        Set objOutlookRecip = .Recipients.Add(strCC)            'CC recipients
        objOutlookRecip.Type = olCC
      End If
   
      .Subject = strSubject                                    'Message subject
      .Body = strMsg & vbCrLf & vbCrLf                          'Message content
      .Importance = olImportanceNormal                          'Message importance

      For Each objOutlookRecip In .Recipients                  'Resolve each Recipient's name
        objOutlookRecip.Resolve
      Next
     
      .Save                                                    'Save message
      .Send                                                    'Send message
    End With
    fhpSendEmail = True                                        'Message sent
  Else                                                          'If not enough information
    strInfoMsg = "Unable to send message because you have supplied to few data!" & vbCrLf & _
                "Info needed are :" & vbCrLf & _
                "Recipient" & vbTab & vbTab & "The person to recieve the mail" & vbCrLf & _
                "Subject" & vbTab & vbTab & "What the mail is about" & vbCrLf & _
                "Message " & vbTab & vbTab & "The text you want to send"
    MsgBox strInfoMsg, vbCritical + vbOKOnly, "Error sendig e-mail"
    fhpSendEmail = False                                        'Message NOT sent
  End If

Exit_fhpSendEmail:
  Set objOutlook = Nothing                                      'Release object
  Set objOutlookMsg = Nothing                                  'Release object
  Set objOutlookRecip = Nothing                                'Release object
  Exit Function

Error_fhpSendEmail:
  fhpSendEmail = False                                          'Message NOT sent
  Select Case Err
    Case Else
      MsgBox Err.Number & ": " & Err.Description, vbOKOnly + vbCritical, "Error in function 'fhpSendEmail'"
      Resume Exit_fhpSendEmail
  End Select

End Function