VBA. flere serie i samme gra ud fra en variable

Fejlen ligger delvist i at jeg ikke fik peget på mit dokument....  Det er nu rettet-
MEN der er stadig dette:
        ActiveChart.SeriesCollection.NewSeries
        ActiveChart.SeriesCollection(2).XValues = _
        WS.Range(WS.Cells(fra1, fra2), WS.Cells(til1, til2))
        ActiveChart.SeriesCollection(2).Values = _
        WS.Range(WS.Cells(fra1, fra2), WS.Cells(til1, til2))

SeriesCollection(2) kan jeg ikke ændre i :-( Jeg ville gerne tælle op fra 1 til x afhængigt af indputtet. Men jeg kan ikke få funktionene til at tage imod en variabel. Er der nogen der har en god ide?

Prøv at vise hele koden - som den ser ud nu.

Sub RecordGraf()
'
' recordGraf Macro
' Macro recorded 24-01-2008 by Gert Sørensen
'
Dim fra1 As Integer
Dim fra2 As Integer
Dim til1 As Integer
Dim til2 As Integer
Dim WS As Worksheet

fra1 = 2 ' Række skal hentes fra variabler  når der er lavet en afrundings variabel
fra2 = 2 ' kolonne
fra3 = 2
fra4 = 2
til1 = 21 ' række
til2 = 2 ' kolonne
til3 = 21
til4 = 2

lop = 2 ' laver 1 serie mere end der skal bruges.

    Charts.Add
    ActiveChart.ChartType = xlXYScatterSmooth
  '  ActiveChart.SetSourceData Source:=Sheets("pumpe5").Range("A1:Z121"), PlotBy _
        :=xlColumns

    Set WS = Worksheets("pumpe5")

    For taller = 0 To lop - 1
   
        ActiveChart.SeriesCollection.NewSeries
        ActiveChart.SeriesCollection(2).XValues = _
        WS.Range(WS.Cells(fra1, fra2), WS.Cells(til1, til2))
        ActiveChart.SeriesCollection(2).Values = _
        WS.Range(WS.Cells(fra3, fra4), WS.Cells(til3, til4))
       
      ' ActiveChart.SeriesCollection(1).XValues = "=pumpe5!R2C3:R21C3"
        'ActiveChart.SeriesCollection(1).Values = "=pumpe5!R2C4:R21C4"
        fra2 = fra2 + 1
        til2 = til2 + 1
        fra4 = fra4 + 1
        til4 = til4 + 1
       
      ' ActiveChart.SeriesCollection.NewSeries
    Next taller
           
    ActiveChart.Location Where:=xlLocationAsObject, Name:="pumpe5"
    With ActiveChart
        .HasTitle = True
        .ChartTitle.Characters.Text = "op"
        .Axes(xlCategory, xlPrimary).HasTitle = True
        .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "hey"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "med dig"
    End With
    ActiveChart.HasLegend = True
End Sub

ja kønt er det ikke ;)

prøv lige den her.
Opretter en ny serie ved hvert loop

og så lige koden :-)

Sub RecordGraf()
'
' recordGraf Macro
' Macro recorded 24-01-2008 by Gert Sørensen
'
    Dim fra1 As Integer
    Dim fra2 As Integer
    Dim til1 As Integer
    Dim til2 As Integer
    Dim WS As Worksheet
    Dim diaFrame As ChartObject
    Dim diaChart As Chart

    Dim MySerie As Series

    fra1 = 2    ' Række skal hentes fra variabler  når der er lavet en afrundings variabel
    fra2 = 2    ' kolonne
    fra3 = 2
    fra4 = 2
    til1 = 21    ' række
    til2 = 2    ' kolonne
    til3 = 21
    til4 = 2

    lop = 2    ' laver 1 serie mere end der skal bruges.

    Set diaFrame = ActiveSheet.ChartObjects.Add(100, 50, 600, 200)
    Set diaChart = diaFrame.Chart
    diaChart.ChartType = xlXYScatterSmooth
    Set WS = Worksheets("pumpe5")

    For taller = 0 To lop - 1

        Set MySerie = diaChart.SeriesCollection.NewSeries
        MySerie.XValues = WS.Range(WS.Cells(fra1, fra2), WS.Cells(til1, til2))
        MySerie.Values = WS.Range(WS.Cells(fra3, fra4), WS.Cells(til3, til4))

        fra2 = fra2 + 1
        til2 = til2 + 1
        fra4 = fra4 + 1
        til4 = til4 + 1
    Next taller

    With diaChart
        .HasTitle = True
        .ChartTitle.Characters.Text = "op"
        .Axes(xlCategory, xlPrimary).HasTitle = True
        .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "hey"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "med dig"
        .HasLegend = True
    End With

End Sub

Det var ellers noget af en slapper du har taget bak
rart at høre fra dig igen. :-)

i lige måde. Nu får vi se om jeg er helt rusten :-)

Med lidt modifikation virker din kode som var den skrevet til formålet bak ;-)

Takker :-)

velbekomme

lukker du den så lige ? :-)