Makro i Word

Eksempel:
Følgende linje vil sætte ombrydning af shape nr. 1, der er markeret, til ombrydning foran tekst:

Selection.ShapeRange(1).WrapFormat.Type = wdWrapFront

Hvis det ikke er tilstrækkeligt til, at du kan tilrette din makro, så vis din nuværende makro. Så er det lettere at hjælpe dig.

makro ser således ud
Selection.InlineShapes.AddPicture FileName:= _
        "C:\Users\ole\Pictures\nr1.png", LinkToFile:=False, SaveWithDocument:= _
        True

Din makro indsætter som "InlineShape", dvs. på linje med tekst. Når det ikke er det, du vil have, skal makroen være anderledes. Du skal indsætte en "Shape".

Det er mere komplekst, end du måske forestiller dig. Der er mange parametre, der kan/skal stilles på. Jeg har lavet nedenstående makro som eksempel - den dækker ikke alle parametre.

Du er nødt til at ændre makroen efter behov. Shapes med ombrydning forskellig fra på linje med tekst er f.eks. forankret til et afsnit, og i makroen her bliver den indsatte shape forankret til første afsnit i dokumnentet (linjen Anchor:=...). Det må du ændre til noget andet om nødvendigt. Desuden har jeg sat en størrelse og placering. Det kan også være nødvendigt at angive den relative placering af den indsatte shape (relativt til siden, margen eller andet).

------------------------MAKRO START------------------------
Sub InsertShapeInFrontOfText()
    Dim oShape As Shape
    Dim strFileName As String
   
    'Change path/file name if needed
    strFileName = "C:\Users\ole\Pictures\nr1.png"
   
    'insert shape in front of text
    'change postion type, anchor location, position and size as needed
    Set oShape = ActiveDocument.Shapes.AddPicture( _
        FileName:=strFileName, _
        SaveWithDocument:=True, _
        Anchor:=ActiveDocument.Paragraphs(1).Range, _
        Left:=CentimetersToPoints(3), _
        Top:=CentimetersToPoints(10), _
        Width:=CentimetersToPoints(15), _
        Height:=CentimetersToPoints(5))
   
    oShape.WrapFormat.Type = wdWrapFront
   
    Set oShape = Nothing
End Sub
------------------------MAKRO SLUT------------------------

NOk mig der ikke fatter noget :)
men når jeg kører makro sker der ikke noget

Er der noget, der fejler? Hvis ikke:
Har du set på side 1 i dokumentet?
Som forklaret bliver billedet (din sti er brugt i makroen) indsat på side 1, da det er linket til første afsnit i dokumentet, og da et billede altid er på samme side som det anker.

Yes yes mange tak, har fået det til at virke
super tak for hjælpen

Nå er der lige igen, er der en måde man kan ændre så den IKKE lander på side 1 men feks. side 2 ?

Hej Igen bare glem det sidste spørgsmål, er klaret , igen tak