Valg i Listbox opdatere tekst i textbox

Private Sub ListBox1_Click()
    TextBox1.Text = ListBox1.Text
End Sub

Hmm, det var vist ikke det du mente. Kan du være mere præcis med hvad der skal hentes hvor på arket og hvad der så skal ske!

så prøver jeg at være lidt mere præcis

har en listbox der hedder lstKortType

With lstKortType
.RowSource = "MATA"
.ListIndex = 0
End With

som her grundlag for denne funktion:

Private Sub cmdOK_Click()
Dim i As Integer
Dim kopidata As String
    A = ActiveSheet.Name
    Sheets(A).Select
    Rows("10:10").Select
    Selection.Insert Shift:=xlDown
    Selection.Insert Shift:=xlDown
    i = lstKortType.ListIndex + 1
    Sheets("DATA").Select
    kopidata = "B" + LTrim(Str(Int(i + 2))) + ":" + "J" + LTrim(Str(Int(i + 2)))
    Range(kopidata).Select
    Selection.COPY
    Sheets(A).Select
    Range("B10").Select
    ActiveSheet.Paste
    Sheets("DATA").Select
    kopidata = "L" + LTrim(Str(Int(i + 2))) + ":" + "T" + LTrim(Str(Int(i + 2)))
    Range(kopidata).Select
    Selection.COPY
    Sheets(A).Select
    Range("B11").Select
    ActiveSheet.Paste
    frmTEST2.Hide
End Sub

men listbox(ene) skal så vise den data man flytter over, i textbox'ene TxtA til TxtH:

  kopidata = "B" + LTrim(Str(Int(i + 3)))
  TxtA.Text = Sheets("DATA").Range(kopidata)
  kopidata = "C" + LTrim(Str(Int(i + 3)))
  TxtB.Text = Sheets("DATA").Range(kopidata)
  kopidata = "E" + LTrim(Str(Int(i + 3)))
  TxtC.Text = Sheets("DATA").Range(kopidata)
  kopidata = "F" + LTrim(Str(Int(i + 3)))
  TxtD.Text = Sheets("DATA").Range(kopidata)
  kopidata = "G" + LTrim(Str(Int(i + 3)))
  TxtE.Text = Sheets("DATA").Range(kopidata)
  kopidata = "H" + LTrim(Str(Int(i + 3)))
  TxtF.Text = Sheets("DATA").Range(kopidata)
  kopidata = "I" + LTrim(Str(Int(i + 3)))
  TxtG.Text = Sheets("DATA").Range(kopidata)
  kopidata = "J" + LTrim(Str(Int(i + 3)))
  TxtH.Text = Sheets("DATA").Range(kopidata)

så det er at tvinge disse til at opdatere ved valg i listboxen...

giver de nogen mening?

Ikke synderligt, for mig ihvertfald.

Er det noget med at nulstille listboxen: lstKortType.Clear
og så tilføje nye værdier:  lstKortType.AddItem txtA.text
                            lstKortType.AddItem txtB.text
osv.

Det her virker for mig, men jeg er ikke helt klar over om dine textboxe er i arket eller på formen

Private Sub cmdOK_Click()
Dim i As Integer, i2 As Integer, i3 As Integer
Dim kopidata As String
Dim wshAct As Worksheet
Dim wshData As Worksheet
  Set wshAct = ActiveSheet
  Set wshData = Worksheets("Data")
  wshAct.Rows("10:11").Insert Shift:=xlDown
  i = CInt(lstKortType.ListIndex + 1)
  i2 = i + 2: i3 = i + 3
  wshData.Range("B" & i2 & ":J" & i2).Copy Destination:=wshAct.Range("B10")
  wshData.Range("L" & i2 & ":T" & i2).Copy Destination:=wshAct.Range("B11")
  With wshData
      Me.txtA.Text = .Range("B" & i3)
      txtB.Text = .Range("C" & i3)
      txtC.Text = .Range("E" & i3)
      txtD.Text = .Range("F" & i3)
      txtE.Text = .Range("G" & i3)
      txtF.Text = .Range("H" & i3)
      txtG.Text = .Range("I" & i3)
      txtH.Text = .Range("J" & i3)
  End With
End Sub

wow, tak! det var noget af et svar, men det var ikke helt det jeg mente, de nævnte textbox'e er i den vba, der indeholder OK knappen, der aktiver "Private Sub cmdOK_Click()"
Alt textboxene skal er at vise den text der flyttes over, hvis man trykker på OK ved den valgte i listboxen "lstKortType", og markere man en anden i listen skal felterne til textboxene så automatisk skifte.

Altså en form for hvis du vælger denne vil følgende data blive sat ind, og så kan man så scroll'e til man finder det der passer og så trykke på OK hvorefter "Private Sub cmdOK_Click()" køres.

...så jeg tror brynil har fat i det rigtige sted, det er nok under click i listboxen koden skal stå

"Er det noget med at nulstille listboxen: lstKortType.Clear" (nej nulstille textboxen)
"og så tilføje nye værdier:  lstKortType.AddItem txtA.text" (ja men i textboxen via. valg i listboxen)

(det kan godt være 100 point var for lidt)

ok, jeg kan ikke se at en nulstilling behøves.

Her er koden, men opdelt

Private Sub lstKortType_Click()
Dim i As Integer, i2 As Integer
Dim kopidata As String
Dim wshData As Worksheet
  Set wshData = Worksheets("Data")
  i = CInt(lstKortType.ListIndex + 1)
  i2 = i + 3
  With wshData
      Me.txtA.Text = .Range("B" & i2)
      txtB.Text = .Range("C" & i2)
      txtC.Text = .Range("E" & i2)
      txtD.Text = .Range("F" & i2)
      txtE.Text = .Range("G" & i2)
      txtF.Text = .Range("H" & i2)
      txtG.Text = .Range("I" & i2)
      txtH.Text = .Range("J" & i2)
  End With
End Sub

Private Sub cmdOK_Click()
Dim i As Integer, i2 As Integer
Dim kopidata As String
Dim wshAct As Worksheet
Dim wshData As Worksheet
  Set wshAct = ActiveSheet
  Set wshData = Worksheets("Data")
  wshAct.Rows("10:11").Insert Shift:=xlDown
  i = CInt(lstKortType.ListIndex + 1)
  i2 = i + 3
  wshData.Range("B" & i2 & ":J" & i2).Copy Destination:=wshAct.Range("B10")
  wshData.Range("L" & i2 & ":T" & i2).Copy Destination:=wshAct.Range("B11")
End Sub

Perfekt!

Skulle kun bruge "Private Sub lstKortType_Click()" men tak for det hele.
den var en foran listboxen så ændrede "i2 = i + 3" til "i2 = i + 2"

takker for hjælpen

smid lige et svar bak så du kan få point (også tak til brynil for at hjælpe)

ok :-)