Tjekke hvilket OS klienten kører

Har du prøvet

strComputer = "."

Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colOperatingSystems = objWMIService.ExecQuery _
    ("Select * from Win32_OperatingSystem")

For Each objOperatingSystem in colOperatingSystems
    Wscript.Echo objOperatingSystem.Caption & " " & _
        objOperatingSystem.Version
Next

Og hvordan holder jeg dem op imod hinanden, altså if xp then or if Win7 then?

Hov, havde ikke lige set din kommentar. Jo, den var prøvet uden held, men så prøvede jeg den igen hvor det virkede.

Det må være noget jeg har glemt at dimisionere første gang.

Men jeg mangler stadig if sætningen, hvordan tjekker jeg for Windows7 og for XP? Har de samme versionsnumre uanset hvilke opdateringer systemerne nu engang har?

isWin7=false
testWin7="Microsoft Windows 7"

isWinXp = false
testWinXP="Microsoft Windows XP" ' sidder ved en win 7 maskine så jeg kender ikke resultatet af denne, så find den rigtige værdi

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")

For Each objOperatingSystem in colOperatingSystems
   
    if Left(objOperatingSystem.Caption,len(testWin7))=testWin7 then
        isWin7=true
    End if
   
    if Left(objOperatingSystem.Caption,len(testWinXP))=testWinXP then
        isWinXP=true
    End if
Next

msgbox isWin7

He he, jeg sidder på en XP maskine, så jeg kan jo test den sidste del.

Nu har jeg dette:

Dim objWMIService, objItem, colItems
Dim strComputer, strList
Dim isWin7, isWinXP, testWinXP, testWin7

isWin7=false
testWin7 ="Microsoft Windows 7"

isWinXp = false
testWinXP ="Microsoft Windows XP" ' sidder ved en win 7 maskine så jeg kender ikke resultatet af denne, så find den rigtige værdi

On Error Resume Next
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")


Set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")

For Each objItem in colItems
    if Left(objItem.Caption,len(testWin7))=testWin7 then
        isWin7=true
    End if
   
    if Left(objItem.Caption,len(testWinXP))=testWinXP then
        isWinXP=true
    End if
Next

msgbox isWin7
msgbox isWinXP

og der får jeg hhv. falsk og sand, så det ser ud til at virke på min XP maskine. Så må jeg lige teste på en Windows 7 maskine i morgen.

Hov, jeg havde helt glemt at vende tilbage vedr. dette spørgsmål. Tofte, det lykkedes at få det til at virke på både XP og Win7, så smider du ikke et svar.

Nå, men så lukker jeg selv.