Outlook - Print af registreret deltager i en mødeindkaldelse

Hej

Hvis du åbner den kalender aftale du ønsker at få overført detaljer på, og kører denne makro så vil den starte excel op og give dig en liste.

Sub seeAtendeeStatus()
    Dim objInspector As Inspector
    Dim objExcel As Excel.Application
    Dim objWorkBook As Excel.Workbook
    Dim objAppItem As AppointmentItem
    Dim i As Integer
    Dim item As Recipient
    Dim status As String
   
    Set objInspector = Application.ActiveInspector
    Set objAppItem = objInspector.CurrentItem
    Set objExcel = New Excel.Application
    Set objWorkBook = objExcel.Workbooks.Add
   
    objWorkBook.Worksheets(1).Range("A1").Value = "Name"
    objWorkBook.Worksheets(1).Range("B1").Value = "Status"
    objWorkBook.Worksheets(1).Range("C1").Value = "Tid"
   
    i = 1
   
    For Each item In objAppItem.Recipients
        Select Case item.TrackingStatus
            Case 0
                status = "Ingen respons"
            Case 2
                status = "Foreløbig accept"
            Case 3
                status = "Accepteret"
            Case 4
                status = "Afslået"
        End Select
        objWorkBook.Worksheets(1).Range("A1").Offset(i).Value = item.Name
        objWorkBook.Worksheets(1).Range("B1").Offset(i).Value = status
        objWorkBook.Worksheets(1).Range("C1").Offset(i).Value = item.TrackingStatusTime
        i = i + 1
    Next
   
    objExcel.Visible = True
   
    Set objInspector = Nothing
    Set objExcel = Nothing
    Set objWorkBook = Nothing
    Set objAppItem = Nothing
    Set item = Nothing
End Sub

Husk at sætte en reference til Microsoft Excel.

/Christian
ck@officekonsulenterne.dk

det vil jeg prøve af tak!

Nu har jeg afprøvet det på 6 maskiner der var kun en maskine jeg ikke kunne få det til at virke på.

Men det virker super Tak.

!

Super godt! :-)

Hej Christian,

Jeg er ikke sikker på om jeg har givet dig dine velfortjente point. Hvis du ikke har så skriv det lige til mig så må jeg finde ud fa det!

Nej det har du nu ikke - men du skal bare aceptere mit svar så får jeg point - selvom jeg nu egentligt er ligeglad med dem :-) Men lad os da endelig holde på formerne... :-)


/Christian