CIO Tech Eksperten IT-JOB IT-Kurser Events Podcast Søg

Log ind eller opret profil

Du kan også logge ind via nedenstående tjenester

madz15 Nybegynder

08. juli 2004 - 13:19 Der er 6 kommentarer og
1 løsning

Viser hvor langt tid der er gået fra en bestemt dato.

Hej,
Jeg søger et script som viser hvor langt tid der er gået fra en bestemt dato.

Hvis jeg f.eks. i scriptet/koden skriver at det var d. 18-01-1985 kl. 03:27 så skriver den at der er gået:
År - måneder - uger - timer - minutter.

Tak.

Synes godt om

ldanielsen Nybegynder

08. juli 2004 - 13:28 #1

Hej igen :o)

Du kan bruge DateDiff

Kan jeg antage at du allerede har den dato som skal undersøges?

Så er det sådan:
<%
'DateToCheck er datoen der skal undersøges

YearsGone = DateDiff("yyyy", Now(), DateToCheck)
MonthsGone = DateDiff("m", Now(), DateToCheck)
WeeksGone = DateDiff("ww", Now(), DateToCheck)
osv

Her er mulige intervaller:
yyyy: Year
q: Quarter
m: Month
y: Day of year
d: Day
w: Weekday
ww: Week of year
h: Hour
n: Minute
s: Second

Tag lige at checkke hvad der sker omkring nytår, jeg er ikke helt sikker

Hvad vil du have? Hvis der er gået et år, to måneder og 3 uger vil den jo fortælle dig at der er gået et år, og at der er gået 14 måneder, og 63 uger (ca.)

Det er ikke det du vil, vel?

Synes godt om

-mundi- Nybegynder

08. juli 2004 - 14:12 #2

sådan her :

<%
session.lcid= 1030
server.scripttimeout = 4
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<title>Untitled</title>
</head>

<body>
<%
datostart = cdate("02-06-1974 13:24:22")
daar=0
dmaaneder=0
duger = 0
ddage=0
dtimer=0
dminutter=0
dsekunder=0

'år
while dateadd("yyyy",1,datostart) < now
datostart=dateadd("yyyy",1,datostart)
daar=daar+1
wend

'måneder
while dateadd("m",1,datostart) < now
datostart=dateadd("m",1,datostart)
dmaaneder=dmaaneder+1
wend

'uger
while dateadd("ww",1,datostart) < now
datostart=dateadd("ww",1,datostart)
duger=duger+1
wend

'dage
while dateadd("d",1,datostart) < now
datostart=dateadd("d",1,datostart)
ddage=ddage+1
wend

'timer
while dateadd("h",1,datostart) < now
datostart=dateadd("h",1,datostart)
dtimer=dtimer+1
wend

'minutter
while dateadd("n",1,datostart) < now
datostart=dateadd("n",1,datostart)
dminutter=dminutter+1
wend

'sekunder
while dateadd("s",1,datostart) < now
datostart=dateadd("s",1,datostart)
dsekunder=dsekunder+1
wend

response.write daar & " " &dmaaneder &" " &duger&" " &ddage&" " &dtimer&" " &dminutter&" "&dsekunder
%>

</body>
</html>

Synes godt om

ldanielsen Nybegynder

08. juli 2004 - 14:20 #3

Smukt og enkelt -mundi-, DateDiff gav mig en MASSE problemer.

Synes godt om

-mundi- Nybegynder

08. juli 2004 - 22:05 #4

madz15 , var det hvad du skulle bruge ?

Synes godt om

tbm_iceman Nybegynder

09. juli 2004 - 01:32 #5

<%
'yyyy - Year
'q - Quarter
'm - Month
'y - Day of year
'd - Day
'w - Weekday
'ww - Week of year
'h - Hour
'n - Minute
's - Second

Dim MyDate, TmpDate, dYears, dMonths, dWeeks, dDays, dHours, dMinutes, dSeconds

Session.LCID = 1030 'Dansk Tid/Valuta Format
MyDate = cDate("10-06-1983 00:00:00")
TmpDate = MyDate
dYears = ModDate("yyyy")
dMonths = ModDate("m")
dWeeks = ModDate("ww")
dDays = ModDate("d")
dHours = ModDate("h")
dMinutes = ModDate("n")
dSeconds = ModDate("s")

Response.Write dYears & " år - " & dMonths & " måneder - " & dWeeks & " uger - " & dDays & " dage - " & dHours & " timer - " & dMinutes & " min. - " & dSeconds & " sec. <br>"

Function ModDate(Interval)
Dim TmpVal
TmpVal = 0
Do Until DateAdd(Interval, 1, TmpDate) > Now
TmpDate = DateAdd(Interval, 1, TmpDate)
TmpVal = TmpVal + 1
Loop
ModDate = TmpVal
End Function
%>

Synes godt om

ldanielsen Nybegynder

09. juli 2004 - 15:43 #6

tbm_iceman > Det er det samme som mundi's, bare med et par twists.

Men det er en god ide at lave en enkelt funktion som kan tage sig af alle dato-delene

Synes godt om

madz15 Nybegynder

10. juli 2004 - 16:47 #7

Jeg brugte -mundi-'s, og den lader til at virke...
Tak

Synes godt om

Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Følg dette spørgsmål

Opret Preview

Programmeringssprog kurser

Kurser inden for grundlæggende programmering

Se alle Programmeringssprog kurser

Flere spørgsmål fra ASP kategorien

Titel	Indlæg	Oprettet	Seneste aktivitet
Lost focus Af bsn i ASP	0	07/11/202415:34	-
ASP classic Af bsn i ASP	8	28/10/202423:11	30/10/202422:51
Classic - filer vist med sidste fil først Af bsn i ASP	5	23/05/202409:56	24/05/202400:02
Optimer MySql table med ASP Af poulmadsen i ASP	4	26/04/202417:16	26/04/202418:37
JSON Af ingeman i ASP	3	07/04/202417:53	08/04/202412:09

Se alle spørgsmål i kategorien Opret spørgsmål

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester

Alle kategorier på Eksperten

Seneste artiklerRSS