Gemme programopsætning og position på skærm

const
  BaseRoot = '\software\myfirm\myapp\';
  RegValue = 'form';

procedure SaveToRegistry(aForm: TForm);
var
  Writer: TWriter;
  Stream: TMemoryStream;
begin
  with TRegistry.Create do
    try
      if OpenKey(BaseRoot + aForm.Name,true) then
      begin
        Stream := TMemoryStream.Create;
        Writer := TWriter.Create(Stream,1024);
        try
          Writer.WriteInteger(aForm.Top);
          Writer.WriteInteger(aForm.Left);
          Writer.WriteInteger(aForm.Width);
          Writer.WriteInteger(aForm.Height);
          Writer.FlushBuffer;
          WriteBinaryData(RegValue,Stream.Memory^,Stream.Size);
        finally
          Writer.Free;
          Stream.Free;
        end;
      end;
    finally
      Free;
    end;
end;

procedure ReadFromRegistry(aForm: TForm);
var
  Reader: TReader;
  Stream: TMemoryStream;
begin
  with TRegistry.Create do
    try
      if OpenKeyReadOnly(BaseRoot + aForm.Name) then
        if ValueExists(RegValue) then
        begin
          Stream := TMemoryStream.Create;
          Reader := TReader.Create(Stream,1024);
          try
            Stream.Size := GetDataSize(RegValue);
            ReadBinaryData(RegValue,Stream.Memory^,Stream.Size);
            Stream.Seek(0,soFromBeginning);
            aForm.Top := Reader.ReadInteger;
            aForm.Left := Reader.ReadInteger;
            aForm.Width := Reader.ReadInteger;
            aForm.Height := Reader.ReadInteger;
          finally
            Reader.Free;
            Stream.Free;
          end;
        end;
    finally
      Free;
    end;
end;

unit UFormDims;

interface

uses
  SysUtils, ContNrs, Classes, Forms, Windows;

type
  TFormDim = class
  const
    Version = 1; // Save version
  strict private
    fTop: integer;
    fLeft: integer;
    fWidth: integer;
    fHeight: integer;
    fName: string;
  public
    constructor Create(aReader: TReader); overload; // Load from file
    constructor Create(aForm: TForm); overload; // Save form
    procedure Restore(aForm: TForm); // Restore form
    procedure Backup(aForm: TForm); // Backup form
    procedure SaveToWriter(aWriter: TWriter); // Save to stream (here a filestream)
    property Name: string read fName;
  end;

  TFormList = class
  strict private
    fList: TObjectList; // Hides properties of the TObjectList
    function IndexOfForm(aForm: TForm): integer;
  private
    function GetItems(const aIndex: integer): TFormDim;
  public
    constructor Create;
    destructor Destroy; override;
    function LoadFromFile(const aFilename: string): boolean;
    procedure LoadFromStream(aStream: TStream);
    function SaveToTile(const aFilename: string): boolean;
    procedure SaveToStream(aStream: TStream);
    procedure Restore(aForm: TForm); // Restore form (wrapper)
    procedure Backup(aForm: TForm); // Backup form (wrapper)
  end;

var
  FormList: TFormList; // Global instance (yirk!)

implementation

const
  FormFile = 'FormDims.dat';

{ TFormDim }

constructor TFormDim.Create(aReader: TReader);
begin
  inherited Create;
  case aReader.ReadInteger of
    1: begin
        fName := aReader.ReadString;
        fTop := aReader.ReadInteger;
        fLeft := aReader.ReadInteger;
        fWidth := aReader.ReadInteger;
        fHeight := aReader.ReadInteger;
      end;
  end;
end;

procedure TFormDim.Backup(aForm: TForm);
begin
  // assert((fName = '') or SameText(fName,aForm.Name));
  fName := aForm.Name;
  fTop := aForm.Top;
  fLeft := aForm.Left;
  fWidth := aForm.Width;
  fHeight := aForm.Height;
end;

constructor TFormDim.Create(aForm: TForm);
begin
  inherited Create;
  Backup(aForm);
end;

procedure TFormDim.Restore(aForm: TForm);
begin
  // assert(SameText(fName,aForm.Name));
  aForm.Top := fTop;
  aForm.Left := fLeft;
  aForm.Width := fWidth;
  aForm.Height := fHeight;
end;

procedure TFormDim.SaveToWriter(aWriter: TWriter);
begin
  aWriter.WriteInteger(Version); // Register save version
  aWriter.WriteString(fName);
  aWriter.WriteInteger(fTop);
  aWriter.WriteInteger(fLeft);
  aWriter.WriteInteger(fWidth);
  aWriter.WriteInteger(fHeight);
  aWriter.FlushBuffer;
end;

{ TFormList }

procedure TFormList.Backup(aForm: TForm);
var
  Index: integer;
begin
  Index := IndexOfForm(aForm);
  if Index < 0 then
    fList.Add(TFormDim.Create(aForm))
  else
    GetItems(Index).Backup(aForm);
end;

constructor TFormList.Create;
begin
  inherited Create;
  fList := TObjectList.Create;
end;

destructor TFormList.Destroy;
begin
  try
    fList.Free;
  finally
    inherited;
  end;
end;

function TFormList.GetItems(const aIndex: integer): TFormDim;
begin
  result := fList[aIndex] as TFormDim;
end;

function TFormList.IndexOfForm(aForm: TForm): integer;
var
  i : integer;
  Found : boolean;
begin
  result := -1; i := -1; Found := false;
  while (i < fList.Count - 1) and not Found do
  begin
    inc(i);
    Found := SameText(GetItems(i).Name,aForm.Name);
  end;
  if Found then
    result := i;
end;

function TFormList.LoadFromFile(const aFilename: string): boolean;
var
  fs: TFileStream;
begin
  result := false;
  if FileExists(aFilename) then
  begin
    fs := TFileStream.Create(aFilename,fmOpenRead);
    try
      LoadFromStream(fs);
      result := true;
    finally
      fs.Free;
    end;
  end;
end;

procedure TFormList.LoadFromStream(aStream: TStream);
var
  i: integer;
  Reader: TReader;
begin
  Reader := TReader.Create(aStream,1024);
  try
    for i := 0 to Reader.ReadInteger - 1 do
      fList.Add(TFormDim.Create(Reader));
    Reader.FlushBuffer;
  finally
    Reader.Free;
  end;
end;

procedure TFormList.Restore(aForm: TForm);
var
  Index: integer;
begin
  Index := IndexOfForm(aForm);
  if Index >= 0 then
    GetItems(Index).Restore(aForm);
end;

procedure TFormList.SaveToStream(aStream: TStream);
var
  i: integer;
  Writer: TWriter;
begin
  Writer := TWriter.Create(aStream,1024);
  try
    Writer.WriteInteger(fList.Count);
    for i := 0 to fList.Count - 1 do
      GetItems(i).SaveToWriter(Writer);
    Writer.FlushBuffer;
  finally
    Writer.Free;
  end;
end;

function TFormList.SaveToTile(const aFilename: string): boolean;
var
  fs: TFileStream;
begin
  result := true;
  try
    fs := TFileStream.Create(aFilename,fmCreate);
    try
      SaveToStream(fs);
    finally
      fs.Free;
    end;
  except
    on e: exception do
    begin
      result := false; // Ignore but return false
      OutputDebugString(pchar(e.Message));
    end;
  end;
end;

initialization
  FormList := TFormList.Create;
  FormList.LoadFromFile(FormFile);

finalization
  FormList.SaveToTile(FormFile);
  FormList.Free;

end.

const
  Version = 1; // Save version

type
  TFormDim = class
  private
    fTop: integer;
  ...