Asp form til txt fil

File System Object (fso), også brug OpenTextFile metoden:
http://msdn.microsoft.com/en-us/library/314cz14s(VS.85).aspx

So du kan se kan den åbne filer "ForAppending" så den skriver sidst i filen:

Const ForReading = 1, ForWriting = 2, ForAppending = 8
Dim fso, f
Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextFile("c:\mappe\testfile.txt", ForAppending, True)
f.WriteLine "konto;navn;adresse1;adresse2;postnr;by;besked;montør1;montør2"
f.Close

En mere generisk metode:

Const ForReading = 1, ForWriting = 2, ForAppending = 8
Dim fso, f, cnt
Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextFile("c:\mappe\testfile.txt", ForAppending, True)
cnt = 0
for each fld in request.form
  if cnt > 0 then f.write ";"
  f.write request.form(fld)
  cnt = cnt + 1
next
f.WriteLine
f.Close


Du kunne også lave en funktion som tager en liste af felter der skal skrives:

function writeForm(filename, fieldlist)
  Const ForReading = 1, ForWriting = 2, ForAppending = 8
  dim fso, f, cnt
  dim rx
 
  set rx = new RegExp
  rx.global = true
  rx.ignorecase = true
  Set fso = CreateObject("Scripting.FileSystemObject")
  Set f = fso.OpenTextFile(filename, ForAppending, True)
  cnt = 0
  for each fld in request.form
    rx.pattern = "(?:^|\;)" & fld & "(?=$|\;)"
    if rx.test(fieldlist) then
      ' hvis feltet findes i feltlisten, så skal det skrives...
      if cnt > 0 then f.write ";"
      f.write request.form(fld)
      cnt = cnt + 1
    end if
  next
  f.WriteLine
  f.Close
end function

writeForm "c:\mappe\testfile.txt","konto;navn;adresse1;adresse2;postnr;by;besked;montør1;montør2"

Hvor er det bare fantastisk. så hurtig svar havde jeg ikke regnet med. :)
Hvis i begge smider et svar så deler jeg lige points mellem jer for fennec har givet mig et godt indblik med hans link og softspot en copy/paste fungerende model. :)

Velbekomme :)

.o) <-- One Eyed Jack

Tak for point :)