Makro der sætter der sætter billeder ind i et word dokument

Hvad er det største problem:
- at lade brugere vælge billed
- at indsætte dette
- tilpasse størrelse og placering?

Prøv at "indspille en makro", der indsætter et billede - så er du på vej...
Ellers giv signal.

MVH

billederne er allerede 4x4cm . mit problem er at jeg skal finde en smart måde at sætte billeder ind, og få dem til at stå ens på alle sider efter den første.

til at starte med ville jeg høre om der er nogen der ved hvordan jeg kan få en makro til.
1. at få et vindu op hvor jeg kan vælge hvilket billede jeg vil sætte ind
2. få billede til at være in front of text
3. give billedet en absolute position

nu har jeg fundet ud af hvordan jeg kan sætte et billede ind med en makro.
Sub indsæt()
'
' indsæt Macro
' Macro recorded 29-10-2004 by aj-labtop
'
    Dialogs(wdDialogInsertPicture).Show
End Sub
nu skal jeg bare have givet det billede jeg sætter ind en absolute position og sætte det til at være In Front Of Text

Du kunne indsætte 4 tekstbokse. Indsæt derefter et bogmærke i hver tekstboks.
Kør derefer denne kode:

Sub IndsætBilleder()
    ActiveDocument.Bookmarks("Nr1").Select
    Dialogs(wdDialogInsertPicture).Show

    ActiveDocument.Bookmarks("Nr2").Select
    Dialogs(wdDialogInsertPicture).Show
   
    ActiveDocument.Bookmarks("Nr3").Select
    Dialogs(wdDialogInsertPicture).Show

    ActiveDocument.Bookmarks("Nr4").Select
    Dialogs(wdDialogInsertPicture).Show
End Sub

Det smarte ved denne metode er at du ikke skal bekymre dig om placering og tekstombrydning - den sætter du på tekstboksen :-)

undskyld det har taget så lang tid men nu har jeg fået testet det nu mangler jeg bare en makro der sætter en testbox på 4X4 cm ind på en absolute position og in front of text.

Hvorfor skal tekstboksen indsættes via kode?

fordi der er ikke altid det same antal text boxe der skal sættes ind

her er et forslag:

Sub Addtextbox()
Dim oRange As Range
Dim oShape As Shape

  Set oRange = Selection.Range
  Set oShape = ActiveDocument.Shapes.Addtextbox _
  (Orientation:=msoTextOrientationHorizontal, _
              Left:=0, Top:=0, Width:=100, Height:=100, _
              Anchor:=oRange)
  With oShape
    .Line.Visible = msoFalse
    .Height = 40
    .Width = 40
    .Left = CentimetersToPoints(15)
    .Top = CentimetersToPoints(17)
  End With
 
  oShape.Select

  ActiveDocument.Bookmarks.Add Range:=Selection.Range, Name:="teksboks1"

  Set oShape = Nothing
  Set oRange = Nothing
End Sub

det er bare for cool det køre. der er lige g2 ting til som jeg håber du kan hjælpe mig med. textboxene skal have en grå baggrund og tildele text boxen et bookmark.

den havde bookmark det havde jeg ikke lige set

Linien:
  ActiveDocument.Bookmarks.Add Range:=Selection.Range, Name:="teksboks1"

indsætter et bogmærke i tekstboksen, så det mangler du vel ikke :-) men du skal selvfølgelig ændre navnet for hver ny tekstboks

Tilføj også:

  With oShape
    .Line.Visible = msoFalse
    .Height = 40
    .Width = 40
    .Left = CentimetersToPoints(Left)
    .Top = CentimetersToPoints(Top)
    .Fill.Solid
    .Fill.ForeColor.RGB = RGB(192, 192, 192)
  End With

altså kun

    .Fill.Solid
    .Fill.ForeColor.RGB = RGB(192, 192, 192)

tak

her har jeg pakket detlind ind, så du kan sætte tekstbaoksene lidt dynamisk :-)
Sub Addtextbox(Left As Integer, Top As Integer, Bogmaerke As String)
Dim oRange As Range
Dim oShape As Shape

ActiveDocument.Bookmarks("Her").Select

  Set oRange = Selection.Range
  Set oShape = ActiveDocument.Shapes.Addtextbox _
  (Orientation:=msoTextOrientationHorizontal, _
              Left:=0, Top:=0, Width:=100, Height:=100, _
              Anchor:=oRange)
  With oShape
    .Line.Visible = msoFalse
    .Height = 40
    .Width = 40
    .Left = CentimetersToPoints(Left)
    .Top = CentimetersToPoints(Top)
    .Fill.Solid
    .Fill.ForeColor.RGB = RGB(192, 192, 192)
  End With
 
  oShape.Select

  ActiveDocument.Bookmarks.Add Range:=Selection.Range, Name:=Bogmaerke
 
  ActiveDocument.Bookmarks("Her").Select
 
  Set oShape = Nothing
  Set oRange = Nothing
End Sub


Sub Indsaettekstboks()

ActiveDocument.Bookmarks.Add Range:=Selection.Range, Name:="Her"

Addtextbox 17, 10, "Nr1"
Addtextbox 17, 20, "Nr2"


End Sub

er det muligt at få den til at udregne position ud fra sidens top og left margins i steden for makøren? og så ville jeg meget gerne hat boxene ikke flyttede sig med teksten. det ville være cool

ret makroen så den ser sådan ud:

With oShape
    .RelativeHorizontalPosition = _
        wdRelativeHorizontalPositionPage
    .RelativeVerticalPosition = _
        wdRelativeVerticalPositionPage
    .LockAnchor = False
    .Line.Visible = msoFalse
    .Height = 40
    .Width = 40
    .Left = CentimetersToPoints(Left)
    .Top = CentimetersToPoints(Top)
    .Fill.Solid
    .Fill.ForeColor.RGB = RGB(192, 192, 192)
End With