Lodtrækning i EXCEL tilfældige tal.

=HELTAL(SLUMP()*32)

Tak for dit svar, desværre virker denne ikke da samme tal fremkommer flere gange.

Undskyld jeg ikke lige skrev det i spørgsmålet...

Skal tallene være forskellige, eller må de godt være ens?

Ok, det har du så svaret på? :0)

Du skal også lige være opmærksom på at funktionen SLUMP skifter værdi hver gang der opdateres.

Tallene skal være forskellige, og må ikke fremkomme flere gange,

Sjap har du en go mulighed?

Du kan kopiere nedenstående funktion ind i dit regneark. Så skal du markere alle 32 celler og trykke F2 og skrive
=randInt(1;32)
Når det er skrevet trykker du Ctrl-Shift-Enter - derved fyldes formlen ud i alle felterne.

Public Function RandInt(Optional ByVal nStart As Long = 1&, Optional ByVal nEnd As Long = -2147483647) As Variant
    Dim vArr As Variant
    Dim vResult As Variant
    Dim nCount As Long
    Dim nTemp As Long
    Dim nRand As Long
    Dim i As Long
    Dim j As Long
    Application.Volatile
    If TypeName(Application.Caller) <> "Range" Then Exit Function
    With Application.Caller
        ReDim vResult(1 To .Rows.Count, 1 To .Columns.Count)
        nCount = .Count
        If nEnd < nStart Then nEnd = nStart + nCount - 1
        If nCount > nEnd - nStart + 1 Then
            RandInt = CVErr(xlErrNum)
            Exit Function
        ElseIf nCount = 1 Then
            RandInt = CLng((nEnd - nStart) * Rnd() + nStart)
            Exit Function
        End If
    End With
    ReDim vArr(0 To nEnd - nStart)
    For i = 0 To UBound(vArr)
        vArr(i) = i + nStart
    Next i
    For i = UBound(vArr) To 1 Step -1
        nRand = Int(Rnd() * (i + 1))
        nTemp = vArr(nRand)
        vArr(nRand) = vArr(i)
        vArr(i) = nTemp
    Next i
    nCount = 0
    For i = 1 To UBound(vResult, 1)
        For j = 1 To UBound(vResult, 2)
            vResult(i, j) = vArr(nCount)
            nCount = nCount + 1
        Next j
    Next i
    RandInt = vResult
End Function

Bemærk at denne funktion har det ligesom SLUMP, så værdierne ændrer sig hver gang der opdateres/genberegnes.

ALTERNATIV:

- Skriv numrene 1 - 32 i f.eks. B1:B32
- I A1 skriver du så =SLUMP() og kopierer denne formel til A2:A32
- Marker A1:B32 og vælg f.eks. "Sorter stigende"

Så vil begge kolonner sorteres efter de tilfældige tal i kolonne A. Fordelen frem for RandInt-funktionen er, at numrene fra 1 til 32 IKKE ændrer sig hver gang der genberegnes.

Hej Sjap.

Jeg forstår ikke helt, Jeg kopier hele den smører der starter med Public function og slutter med End Function ind et vilkårligt sted i regnearket.

Derefter trykker jeg =randInt(1;32) ind så der kommer til at stå " =randint(1;32)navn " i kolonne 1  og " =randInt(1;32) lønnummer " i kolonne 2, det sker der ikke rigtigt noget med.

Skulle den lave en kolonne 3 med det tilfældige nummer i? jeg kan ikke se at der overhovede er en kommando der hedder noget med =randInt(1;32)

Tak fordi du gider bruge tid på det ::-)

Det er mig der er lidt utydelig.

Funktionen som du skal kopierer skal sættes ind på følgende måde:

- Tryk F11 for at starte VBA-editoren
- I menuen vælges Indsæt og herunder vælges Modul
- I det hvide område indsætter du så hele funktionen RandInt

Først når du har gjort det, er RandInt klar til brug i regnearket.

I den første celle skal der kun stå

=RandInt(1;32)

Hverken mere eller mindre. Når du så trykker Ctrl-Shift-Enter så kommer der tuborg-klammer omkring

{=randInt(1;32)}

Det betyder blot at det er en matrixformel (dvs. en formel, der påvirker flere celler samtidigt)

Marker dine 32 celler og kør denne makro

Public Sub Rand32()
Dim Sel As Variant
Sel = Selection
For i = 1 To UBound(Sel)
OM:
V = Int(Rnd * 32) + 1
Sel(i, 1) = V
If i > 1 And i < 33 Then
For A = 1 To i - 1
If Sel(A, 1) = V Then GoTo OM
Next
End If
Next
Selection = Sel
End Sub

Her er en der lacer tilfældig over det antal celler der er makeret.
Markering kun i 1 kolonne

Public Sub Rand32()
Dim Sel As Variant
Sel = Selection
Maks = UBound(Sel)
For i = 1 To Maks
OM:
V = Int(Rnd * Maks) + 1
Sel(i, 1) = V
If i > 1 And i < Maks + 1 Then
For A = 1 To i - 1
If Sel(A, 1) = V Then GoTo OM
Next
End If
Next
Selection = Sel
End Sub

ok

var der ikke noget du kunne bruge, siden du tog point selv. ????

Det er da flot. Og ikke engang et ord om hvad årsagen er! Blot et fjollet lille "ok"! Det lugter lidt.

Gammel tråd, men altid en fornøjelse at finde det man søger.

Nu fik du tilsyneladende ingen point dengang (uvist hvorfor)... så vil da gerne lige komme med en tak i det mindste!