Replace tekst

Jeg en funktion til at lave email og links om til klikbare link så det da bare et tilføje flere ting til den eks:


Function makeHTMLstr(strInput)
Set objRegExpHTTP1 = New RegExp
Set objRegExpHTTP2 = New RegExp
Set objRegExpEMail = New RegExp

objRegExpHTTP1.Pattern = "(http|ftp|https)(:\/\/[\w]+)(.[\w]+)([\w\-\.,@?^=%&:/~\+#]*[\w\-\@?^=%&/~\+#])?"
objRegExpHTTP2.Pattern = "(^|[^\/])(www)(.[\w]+)([\w\-\.,@?^=%&:/~\+#]*[\w\-\@?^=%&/~\+#])?"
objRegExpEMail.Pattern = "([\w\._-]+@[\w\._-]+\.[A-Za-z]{2,3}\S*)"

objRegExpHTTP1.Global = True
objRegExpHTTP2.Global = True
objRegExpEMail.Global = True

objRegExpHTTP1.IgnoreCase = True
objRegExpHTTP2.IgnoreCase = True
objRegExpEMail.IgnoreCase = True

strOutput = objRegExpHTTP1.Replace(strInput, "<a href='$1$2$3$4' target='_blank'>$1$2$3$4</a>")
strOutput = objRegExpHTTP2.Replace(strOutput, " $1<a href='http://$2$3$4' target='_blank'>$2$3$4</a>")
strOutput = objRegExpEMail.Replace(strOutput, " <a href='mailto:$1'>$1</a> ")

Set objRegExpHTTP2 = Nothing
set objRegExpHTTP1 = Nothing
Set objRegExpEMail = Nothing

'Laver vbCrLf linjesift om til <br> så browseren kan vise returns:

strOutput = Replace(strOutput,vbCrLf,"<br>")

'Laver smiles om til billeder, du skal nok lige rette sti og filnvn til så det passer til din side

strOutput = Replace(strOutput,":)","<img src=""/billeder/smily.gif"">")
strOutput = Replace(strOutput,":-)","<img src=""/billeder/smily.gif"">")
strOutput = Replace(strOutput,":(","<img src=""/billeder/sur.gif"">")
strOutput = Replace(strOutput,":-(","<img src=""/billeder/sur.gif"">")
strOutput = Replace(strOutput,";)","<img src=""/billeder/wsmily.gif"">")
strOutput = Replace(strOutput,";-)","<img src=""/billeder/wsmily.gif"">")
strOutput = Replace(strOutput,"8)","<img src=""/billeder/briller.gif"">")
'..Tilføje flere her


'retuner resultatet
makeHTMLstr = strOutput
End Function

Det ser rigtig fornuftig ud.
Jeg kan bare include det script der, ik? - men hvad skal jeg skrive i de input-felter som skal være påvirket af scriptet?

Det er en funktion, du kan ligge den i bunden af din fil.
Hvis du vil lave det om når du henter fra input-felterne kan du gøre eksempelvis sådan her:

besked = makeHTMLstr(Request.Form("besked"))

Nok mig der er en hat, men det virker ik.

Skal jeg give mine forms et navn som passer til funktionen eller lignende?

Hvis du har et form felt som dette:

<textarea name="besked"></textare>


På den side hvor du gemmer det i databasen har du sikkert noget som dette i dag:

besked = Request.Form("besked")


Det udvider du til dette:

besked = makeHTMLstr(Request.Form("besked"))

Men du kan jo gemme teksten rå og først lave det om når du udskriver teksten. Det har den fordel hvis du laver et folder navn om eller skifter billede filnavn så vil det stadig virke.

Nej, har nu f.eks. sådan en her:

rs("username") = Server.HTMLEncode(Request("username"))

- Har prøvet med "besked = makeHTMLstr(Request.Form("besked"))" blandt dem, men der sker stadig intet. Den skriver fint i databasen, men den benytter sig ikke af funktionen..

Hvordan ser din SQL sætning så ud?

Set rs = Server.CreateObject("ADODB.Recordset")
    strSQL = "select * from news"
    rs.Open strsql, conn, 1, 3

Håber det er den du mener :)

Måske, bruger du rs.AddNew så?
hvordan ser linjen ud hvor du gemmer det input felt som ikke virker?

Jep, bruger rs.AddNew

<textarea cols="54" rows="10" name="comment"  name="besked"></textarea>

sludder - unden comment self.. :)

men hvordan ser linjen ud som gemmer comment??

rs("comment") = xxxx

HVis der står:

rs("comment") = request.form("comment")


Skal det være der funktionen klades sådan her:

rs("comment") = makeHTMLstr(request.form("comment"))

rs("comment") = Server.HTMLEncode(Request("comment"))

Ja, det kan jeg godt se nu du siger det.. Prøver lige ad..

Ja det går så ikke at bruge Server.HTMLEncode efter man har kladt makeHTMLstr for den vil ødelægge links og billede tags så man skal havde dem kaldt sådan her:

rs("comment") = makeHTMLstr(Server.HTMLEncode(Request("comment")))

For fanden ja! :) - Du er dagens mand i skysovs.

Svar for point og tusinde tak for hjælpen..

Ok :)