Gennemsnit over sidste 4 uger

Prøv med:

=MIDDEL(C1:BB1)

utestet:
=middel(kolonne(tæl(række()):kolonne(tæl(række()-3)))

Til andyness
Din formel tager et gennemsnit af alle uger, også selvom der endnu ikke har været salg i alle uger.

Til finb
Jeg kan ikke få den til at virke, kan ikke gennemskue hvor det går galt.

Hvis celler uden salg er tomme, tæller min formel kun celler med salg med.

Hvis der står "0" i celler uden salg endnu, og 0'et ikke skal tælles med, så prøv med denne:

=MIDDEL.HVIS(C1:BB1;"<>0")

Har ikke lige Excel her.
Tæl, hvor mange celler i rækken, der har tal, fx 8 celler.
Det er så kolonne 8+2 = kolonne 10, der er sidste
kolonne med tal i.
Du skal bruge et middel af tallene fra kolonne 7 til 10.

Mon denne ikke Kan hvad du vil

=(INDEKS(C1:BC1;1;UGE.NR(IDAG())-4)+INDEKS(C1:BC1;1;UGE.NR(IDAG())-3)+INDEKS(C1:BC1;1;UGE.NR(IDAG())-2)+INDEKS(C1:BC1;1;UGE.NR(IDAG())-1))/4

Jan

Med dine data i række 2 prøv denne matrixformel:

=MIDDEL($BB$2:INDEKS($A$2:$BB$2;STØRSTE(KOLONNE($A$2:$BB$2)*($A$2:$BB$2<>"");4)))

Ved indtastning af formlen husk at holde Ctrl og Shift nede før tryk på Enter.

Prøv: FORSKYDNING(reference;rækker;kolonner;[højde];[bredde])

=MIDDEL(FORSKYDNING(C1;0;UGE.NR(IDAG()); 1; -4))

Jeg kan desværre ikke få noget af det til at virke

https://www.dropbox.com/s/ajzzeaptoold3bu/Gennemsnit_sidste_fire.xlsx?dl=0

Flot lavet xl-Enthusiast gad vide hvorfor det giver 3 forskellige resultater ;-)

@Jan Hansen

I den uploadede fil:

#6 returnerer gennemsnittet af AG2:AJ2
#7 returnerer gennemsnittet af AH2:AK2
#8 returnerer gennemsnittet af AI2:AL2

Min formel bruger C2 som reference punkt (Uge 1) dette er en fejl.

Skal rettes til B2
=MIDDEL(FORSKYDNING(B2;0;UGE.NR(IDAG()); 1; -4))

Så den returnerer gennemsnittet af AH2:AK2 som bliver: 742,25

UGE.NR(IDAG()) udskiftet med 35

=MIDDEL(FORSKYDNING(B2;0;35; 1; -4))

FORSKYDNING(B2;0 = ingen forskydning på række niveau (Række 2)
FORSKYDNING(B2;0;35 = forskydning 35 til højre for B2 (Celle AK2)
FORSKYDNING(B2;0;35; 1 = 1 række (Række 2)
FORSKYDNING(B2;0;35; 1; -4 = +4 celler til venstre for AK2 (Cellerne AH2:AK2)

=MIDDEL(AH2:AK2)

Ps.
Resultat i xl-Enthusiast eksempel ark ændre sig hele tiden, da han har brugt formlen:
=SLUMPMELLEM(100;1000) 

;-)

Sjovt, 3 forskellige løsninger der giver samme resultat, en opgave kan angribes fra mange forskellige vinkler.

Jan

Ja, "many ways to skin a cat", men bemærk dog, at formlerne virker forskelligt,

Hvis for eksempel
AG2 = 273
AH2 = 937
AI2 = blank
AJ2: 661 og
AK2 = 904

Så vil #6 (korrigeret) returnere =(AH2+0+AJ2+AK2)/4 = 625,5

#7 vil returnere =MIDDEL(AG2;AH2;AJ2;AK2) = MIDDEL(273;937;661;904) = 693,75 (det vil sige summen af sidste fire ikke tomme celler)

#8 vil returnere =MIDDEL(AH2:AK2) = MIDDEL(937;661;904) = 834.

Hvad der værst eller bedst afhænger selvsagt af situationen. Her er #8 formentlig bedst. I en anden situation (for eksempel golfregnskab, hvor ikke nødvendigvis alle deltager hver gang) vil man have behov for noget i stil med #7.