Hente antalvisninger fra YouTube

Jeg har splittet spørgsmålet lidt op, så jeg i dette spg: http://www.eksperten.dk/spm/1007908 vil lave en funktion på min server der kan modtage et youtube ID og returnere antallet af visninger på en hjemmeside.

Jeg er derfor i dette spørgsmål ude efter hjælp til at lave excel delen, hvor den løber cellerne igennem, sender ID'et til en hjemmeside og får antal visninger retur.

Er ved at eksperimentere med udfordringen - har du et eksempel på YouTube, som jeg kan teste med.

Hej Supertekst,

Det kan være en hvilken som helst video, så enhver burde kunne bruges som test :)

Rem En del af koden - p.t. kun 1 YouTube-id og opkald hertil

Rem Ekstra referencer er sat: Microsoft Internet Controls & Microsoft HTML Object Library
Rem VBA-koden er anbragt under det relevante ark i Excel

Dim Tekst As String, vTekst As String, tabel As Variant, x As Long, tæller As Long
Const ytKode = "jxzpgxd6qSY"
Sub testHentFraYT()
  tæller = hentTællerFraYouTube(ytKode)
End Sub
Private Function hentTællerFraYouTube(ytKode)
Dim ie As InternetExplorer
Dim html As HTMLDocument

    Set ie = New InternetExplorer
    ie.Visible = False
    ie.Navigate "https://www.youtube.com/watch?v=" & ytKode

    Do While ie.ReadyState <> READYSTATE_COMPLETE
        Application.StatusBar = "Vent venligst..."
        DoEvents
    Loop

    Set html = ie.Document
    ie.Visible = False
   
    Tekst = html.DocumentElement.innerHTML
   
    x = InStr(Tekst, "view-count")
    vTekst = Mid(Tekst, x + 12)
    tabel = Split(vTekst, "<")
    hentTællerFraYouTube = tabel(0)

    Set ie = Nothing
    Application.StatusBar = ""
End Function

Super fedt at du giver det et skud.

Jeg skal lige høre, hvordan sætter jeg det ind i Excel, så jeg kan få den til at kører, og hvordan vil jeg kunne sætte det op så den gennemløber en hel kolonne med youtube videoer, og indsætter viewcount hele vejen ned?

For at sætte koden ind:
Højreklik på det relevante ark / vælg vis programkose / indsæt koden

For at køre makroer:
Under Excel indstillinger / sikkerhedscenter / tillad anvendelse af makroer

Indsæt de nævnte referencer:
Alt+F11 / VBA vinduet vises / i menuen under Tools / referencer / sæt x ved de 2 nævnte - er i alfabetisk rækkefølge  - gem

For at prøve koden p.t.:
I VBA vinduet under arket kan koden ses / placer markøren i den øverste SUB. Indsæt en stopklods ved at klikke på den grå ramme til venstre for End Sub. Her stopper processen så efter gennemløbet og ved at pege på variablen tæller med musen - kan værdien aflæses. Men først startes gennemløbet med F5

NB alt dette fordi resten af koden til automatisk udførelse endnu ikke er udført - kommer snarest.

Hvis du foretrækker det kan du sende en mail så returnerer jeg min model p.t. @-adresse under min profil.

fantastisk, har endt dig en mail :)

Rem Version 2 - 17-12-15
Rem Ekstra referencer er sat: Microsoft Internet Controls & Microsoft HTML Object Library

Const startRække = 2                                'kan evt. justeres
Const startKolonne = 2                              '- " -
Dim antalKolonner As Integer, antalRækker As Integer, ræk As Integer, ytLink As String
Dim Tekst As String, vTekst As String, tabel As Variant, x As Long, tæller As Long
Sub HentFraYT()
    antalKolonner = ActiveCell.SpecialCells(xlLastCell).Column
    antalRækker = ActiveCell.SpecialCells(xlLastCell).Row
   
    For ræk = startRække To antalRækker
        ytLink = Range("A" & ræk)
        tæller = hentTællerFraYouTube(ytLink)
        indsætIkolonne tæller, ræk
    Next ræk
   
    ActiveSheet.Columns.AutoFit
End Sub
Private Sub indsætIkolonne(tæller, ræk)
Dim kol As Integer, mDåR As String
    mDåR = Format(Now, "mmm-yy")
   
    For kol = 2 To antalKolonner
        If Format(Cells(1, kol), "mmm-yy") = mDåR Then
            Cells(ræk, kol) = tæller
            Exit Sub
        End If
    Next kol
End Sub
Private Function hentTællerFraYouTube(ytKode)
Dim ie As InternetExplorer
Dim html As HTMLDocument

    Set ie = New InternetExplorer
    ie.Visible = False
    ie.Navigate "https://www.youtube.com/watch?v=" & ytKode

    Do While ie.ReadyState <> READYSTATE_COMPLETE
        Application.StatusBar = "Vent venligst..."
        DoEvents
    Loop

    Set html = ie.Document
    ie.Visible = False
   
    Tekst = html.DocumentElement.innerHTML
   
    x = InStr(Tekst, "view-count")
    vTekst = Mid(Tekst, x + 12)
    tabel = Split(vTekst, "<")
    hentTællerFraYouTube = tabel(0)

    Set ie = Nothing
    Application.StatusBar = ""
End Function
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Address = "$A$1" Then
        Cancel = True
        HentFraYT
    End If
End Sub