Flyt og slette række i ark1 til ark2 og sotere dette.

Ja - via en makro
Du er velkommen til at sende en model. @-adresse under min profil
- så skal jeg forsøge.

Rem VBA-koden anbringes under første ark
rem Højrekllik på fanen / Vis programkode / indsæt her / Gem og Luk

Option Explicit
Dim række As Integer, ledigRække As Integer, antalRækker As Integer
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Column = 10 And IsDate(Target) = True And InStr(Target.Address, ":") = 0 Then
        ActiveWorkbook.Sheets("Afsluttede").Activate
        ActiveSheet.Range("J1").Select
        Selection.AutoFilter                          'slå autofilter fra på side 2
       
        ActiveWorkbook.Sheets("Alle indkomne").Activate
        række = Target.Row
        ActiveSheet.Rows(række & ":" & række).Activate
        Selection.Copy
       
        ActiveWorkbook.Sheets("Afsluttede").Activate
       
Rem Søg tom celle i kolonne A
        ActiveSheet.Range("A1").Select
        antalRækker = ActiveCell.SpecialCells(xlLastCell).Row
       
        ledigRække = findRække("Afsluttede", "A1:A" & antalRækker, "")
        ActiveSheet.Range("A" & ledigRække).Select
        ActiveSheet.Paste
        Application.CutCopyMode = False

Rem sortering lægges her
        sortering (ledigRække)

Rem Slet rækken med afsluttet opgave
        ActiveWorkbook.Sheets("Alle indkomne").Activate
        ActiveSheet.Rows(række & ":" & række).Activate
        Selection.Delete
    End If
End Sub
Private Sub sortering(sidsteRække)
    ActiveWorkbook.Worksheets("Afsluttede").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Afsluttede").Sort.SortFields.Add Key:=Range( _
        "J1:J" & sidsteRække), SortOn:=xlSortOnValues, Order:=xlDescending, DataOption:= _
        xlSortNormal
    With ActiveWorkbook.Worksheets("Afsluttede").Sort
        .SetRange Range("A1:J" & sidsteRække)
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End Sub
Private Function findRække(ark, område, værdi)
Dim c As Object
    With ActiveWorkbook.Sheets(ark).Range(område)
        Set c = .Find(værdi, LookIn:=xlValues, LookAt:=xlWhole)
        If Not c Is Nothing Then
            findRække = c.Row
        Else
            findRække = 0
        End If
    End With
End Function

Det er super, lige som jeg ønskede :)

Mange tak for hjælpen.

Selv tak..