Felt i tabel der regner forskel mellem to datoer ud?!

Der er en rimelig god artikel om dette
http://msdn.microsoft.com/en-us/library/office/dd327646%28v=office.12%29.aspx

Det korte svar er at det godt kan laves - men det er ikke bare lige.....

Hej Hugo

Tak for artiklen, den er helt sikkert rette vej.

Jeg har lavet tabellerne og klippet VBA koden ind i VBA module...

Men den kommer ikke ud med regnestykket.

Hvad skal jeg gøre i workdays feltet for at den kommer frem til dagenene...?

Fanger ikke helt det de skriver om Datdiff mv.

NB:
Har klibbet disse to moduler ind:

Public Function Weekdays(ByRef startDate As Date, _
    ByRef endDate As Date _
    ) As Integer
    ' Returns the number of weekdays in the period from startDate
    ' to endDate inclusive. Returns -1 if an error occurs.
    ' If your weekend days do not include Saturday and Sunday and
    ' do not total two per week in number, this function will
    ' require modification.
    On Error GoTo Weekdays_Error
   
    ' The number of weekend days per week.
    Const ncNumberOfWeekendDays As Integer = 2
   
    ' The number of days inclusive.
    Dim varDays As Variant
   
    ' The number of weekend days.
    Dim varWeekendDays As Variant
   
    ' Temporary storage for datetime.
    Dim dtmX As Date
   
    ' If the end date is earlier, swap the dates.
    If endDate < startDate Then
        dtmX = startDate
        startDate = endDate
        endDate = dtmX
    End If
   
    ' Calculate the number of days inclusive (+ 1 is to add back startDate).
    varDays = DateDiff(Interval:="d", _
        date1:=startDate, _
        date2:=endDate) + 1
   
    ' Calculate the number of weekend days.
    varWeekendDays = (DateDiff(Interval:="ww", _
        date1:=startDate, _
        date2:=endDate) _
        * ncNumberOfWeekendDays) _
        + IIf(DatePart(Interval:="w", _
        Date:=startDate) = vbSunday, 1, 0) _
        + IIf(DatePart(Interval:="w", _
        Date:=endDate) = vbSaturday, 1, 0)
   
    ' Calculate the number of weekdays.
    Weekdays = (varDays - varWeekendDays)
   
Weekdays_Exit:
    Exit Function
   
Weekdays_Error:
    Weekdays = -1
    MsgBox "Error " & Err.Number & ": " & Err.Description, _
        vbCritical, "Weekdays"
    Resume Weekdays_Exit
End Function

-------

Public Function Workdays(ByRef startDate As Date, _
    ByRef endDate As Date, _
    Optional ByRef strHolidays As String = "Holidays" _
    ) As Integer
    ' Returns the number of workdays between startDate
    ' and endDate inclusive.  Workdays excludes weekends and
    ' holidays. Optionally, pass this function the name of a table
    ' or query as the third argument. If you don't the default
    ' is "Holidays".
    On Error GoTo Workdays_Error
    Dim nWeekdays As Integer
    Dim nHolidays As Integer
    Dim strWhere As String
   
    ' DateValue returns the date part only.
    startDate = DateValue(startDate)
    endDate = DateValue(endDate)
   
    nWeekdays = Weekdays(startDate, endDate)
    If nWeekdays = -1 Then
        Workdays = -1
        GoTo Workdays_Exit
    End If
   
    strWhere = "[Holiday] >= #" & startDate _
        & "# AND [Holiday] <= #" & endDate & "#"
   
    ' Count the number of holidays.
    nHolidays = DCount(Expr:="[Holiday]", _
        Domain:=strHolidays, _
        Criteria:=strWhere)
   
    Workdays = nWeekdays - nHolidays
   
Workdays_Exit:
    Exit Function
   
Workdays_Error:
    Workdays = -1
    MsgBox "Error " & Err.Number & ": " & Err.Description, _
        vbCritical, "Workdays"
    Resume Workdays_Exit
   
End Function

Har du mulighed for at sende mig din db, så skal jeg prøve at se om jeg kan fikse det

oz8hp  snabelfidus  hotmail  prik  com

Det vil være super.
Jeg har sendt dig filen.
Mange tak fordi du vil hjælpe.

Og din fil er på vej retur

Resultaten af beregningerne kan ses i forespørgslen Query1

tusind tak - det fungerer 100% - glæder mig til at se nærmere efter i koden hvordan du fik det til at fungere og lære!

Sender du svar.

Det største 'problem' var nok at du havde givet funktionerne nye navne.
Så skal man lige huske at ændre alle steder :-)

ahh, bedre at bruge standarden indtil mjeg har styr på det ;-)

Når det er VBA så har du mulighed for at compile/debugge (kan ikke lige huske hvor det er i menuen) så burde den have fanget den fejl.

Tak for point