Hente både organisation og bruger ud fra AD?

Hej ptj_11

Følgende skulle gerne give dig et resultat som du kan bruge

I det oprindelige script manglede der et punktum i linien

objCommand.Properties("Sort On") = "Name"

Sig til hvis der er yderligere jeg har overset ;)

On Error Resume Next

Const ADS_SCOPE_SUBTREE = 2

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =  CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection

objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
objCommand.Properties("Sort On") = "Name"

objCommand.CommandText = _
    "SELECT Name, Company, Department, AdsPath, Title FROM 'LDAP://dc=KA,dc=KK' WHERE objectCategory='user'" 

Set objRecordSet = objCommand.Execute

objRecordSet.MoveFirst
Do Until objRecordSet.EOF
    Wscript.Echo objRecordSet.Fields("AdsPath").Value &_
    vbTab & "user=" & objRecordSet.Fields("Name").Value &_
    vbTab & "company=" & objRecordSet.Fields("Company").Value &_
    vbTab & "department=" & objRecordSet.Fields("Department").Value &_
    vbTab & "title=" & objRecordSet.Fields("Title").Value
    objRecordSet.MoveNext
Loop

Hilsen dr-data

Hej dr-data.

Jeg kan ikke lige forstå denne:

I det oprindelige script manglede der et punktum i linien

objCommand.Properties("Sort On") = "Name"

Jeg synes ikke at jeg kan se, at du har indsat en punktum i det nye script, men never mind, det virker. Den sidder lige i skabet.

Du skal have så mange tak for hjælpen.
Normalt er jeg her primært for at hjælpe andre, men hvor det lækkert, når man står med et problem, at hjælpen er lige om hjørnet, når man render ind i et problem, hvor man selv er ren novice.
/ptj_11

Hej ptj_11

Det er bare super :)

Det er bare et mellemrum der manglede..

Ved at fjerne linien "on error resume next", fortalte "fortolkeren", at der var fejl på denne linie..

/dr-data