Ikonsæt i betinget formatering - Relative referancer

Så vidt jeg kan se skal du blot fjerne dollar tegnene i den betingende formattering. Altså:
rød pil: når værdien i cellen er > B72
gul pil: når værdien i cellen er = B72
grøn pil: når værdien i cellen er < B72

Det er det der er problemet - det kan man ikke:-)

Løser denne makro dit problem?

Bemærk du lige skal rette "Sheet1" til hvad dit ark nu hedder.
Og jeg har antaget at det er en fejl at du skriver at række 58 skal sammenlignes med 127 - det bør umiddelbart være 126 (så der er 68 rækker i mellem rækken med formatteringen og den række der sammenlignes med).

Public Sub SetIconSet()
    Dim cfIconSet As IconSetCondition
    Dim rn As Range
   
    Dim startRow As Integer
    Dim startCol As Integer
    Dim endRow As Integer
    Dim endCol As Integer
   
    Dim row As Integer
    Dim col As Integer
   
    Dim compareRowoffset As Integer
    Dim compareRef As String
   
    startRow = 4
    endRow = 58
    startCol = 2 ' B
    endCol = 13 ' M
   
    compareRowoffset = 68
   
    For row = startRow To endRow
        For col = startCol To endCol
            Set rn = Worksheets("Sheet1").Cells(row, col)
            compareRef = "=" & rn.Offset(compareRowoffset, 0).Address
           
            rn.FormatConditions.Delete
           
            Set cfIconSet = rn.FormatConditions.AddIconSetCondition
            cfIconSet.IconSet = ActiveWorkbook.IconSets(xl3Arrows)
            cfIconSet.ReverseOrder = True
            With cfIconSet.IconCriteria(3)
                .Type = xlConditionValueNumber
                .Value = compareRef
                .Operator = xlGreater
            End With
           
            With cfIconSet.IconCriteria(2)
                .Type = xlConditionValueNumber
                .Value = compareRef
                .Operator = xlGreaterEqual
            End With
       
        Next col
    Next row

End Sub

Fjern $ foran B

Sådan:

rød pil: når værdien i cellen er > B$72
gul pil: når værdien i cellen er = B$72
grøn pil: når værdien i cellen er < B$72

Jeg mener nu godt at du kan bruge Jens48s løsning. Du skal bare lave den formatering i den første celle, og så kopiere den ud....det har jeg prøvet, og det virkede i excel 2003 anyway.

til anlu

Super det virker jo - hvordan giver jeg dig point?

Takker mange gange

Jesper

Glad for at kunne hjælpe :o)
Du giver point, ved at acceptere dette svar.