Du kan bruge en makro i Word til at oprette dokumenterne. Jeg har lavet en her - se kommentarerne i selve makroen.
Du skal køre makroen, _efter_ at du har lavet brevfletningen (flet til nyt dokument), og det flettede dokument skal være det aktive dokument. Du behøver ikke at gemme det flettede dokument - så vil det bare blive lukket uden at blive gemt til sidst. Der er ikke længere flettefelter i det flettede dokument, så teksten til filnavne er i makroen taget fra første afsnit i hvert brev. Hvis det ønskede står et andet sted i brevet, skal du rette i makroen.
Makroen vil oprette et nyt dokument for hver sektion i det flettede dokument (= hver post). Dokumenterne bliver gemt i den mappe, der er angivet i selve makroen (lav om, så det passer dig).
Du kan få brug for fejlhåndtering, som ikke er bygget ind her. Hvis der f.eks. er to ens navne, må du lave noget til at håndtere det - men nu har du noget at tage udgangspunkt i.
Hvis du har brug for hjælp til at installere makroen, se:
http://word.mvps.org/faqs/macrosvba/CreateAMacro.htm Sub MailMerge_OneDocPerLetter()
'First perform mail merge to new document, then run this macro
'to save each letter as a separate file
Dim strDocName As String
Dim oDoc As Document
Dim oDocNew As Document
Dim strFileName As String
Dim strFilePath As String
Dim nSections As Long
Dim nCount As Long
Set oDoc = ActiveDocument
nSections = oDoc.Sections.Count
'Replace path with the folder path to use
strFilePath = "C:\MyLetters\"
nCount = 1
Application.ScreenUpdating = False
While nCount < nSections
'Change the code line below if the name is found elsewhere
strDocName = oDoc.Paragraphs(1).Range.Text
'exclude parapraph mark
strDocName = Left(strDocName, Len(strDocName) - 1)
'append til path - replace ".doc" with ".docx" if file format must be 2007 or 2010
strDocName = strFilePath & strDocName & ".doc"
'cut section 1 and insert in new document
oDoc.Sections.First.Range.Cut
Set oDocNew = Documents.Add
With oDocNew
'make sure document is empty
.Range.Text = ""
'insert cut text
Selection.Paste
'save document with correct name
.SaveAs FileName:=strDocName, FileFormat:=wdFormatDocument, _
LockComments:=False, Password:="", _
AddToRecentFiles:= _
True, WritePassword:="", ReadOnlyRecommended:=False, _
EmbedTrueTypeFonts:= _
False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
SaveAsAOCELetter:=False
.Close
End With
nCount = nCount + 1
Wend
'close the now empty oDoc without saving
oDoc.Close savechanges:=wdDoNotSaveChanges
'clean up
Set oDoc = Nothing
Set oDocNew = Nothing
Application.ScreenUpdating = True
MsgBox "Finished. Documents saved in folder:" & vbCr & _
strFilePath
End Sub
