Replace virker ikke - RegExp måske?

Hvad er det du skal have udskrevet i dit eksempel?

I eksemplet vil det være:

<a id="bbb23456">bbb23456</a><a id="ccc34567">ccc34567</a></td>
    </tr>
</table>


og derefter:

<a id="ccc34567">ccc34567</a></td>
    </tr>
</table>

Jeg formoder det er gammeldags ASP, med VBScript. Ikke just "state-of-the-art", men det kan da bringes til at virke, hvis jeg forstår dig rigtigt.

På http://asp.n0p.com/919872.asp kører dette lille script:

<%

a = "<table>" & vbcrlf &  _
    "<tr>" & vbcrlf & _
    "<td><a id=""abc12345"">abc12345</a><a id=""bbb23456"">bbb23456</a><a id=""ccc34567"">ccc34567</a></td>" & vbcrlf & _
    "</tr>" & vbcrlf & _
    "</table>"
   
response.write server.htmlencode(a)

response.write "<hr><br>"

Set myRegExp = New RegExp
myRegExp.IgnoreCase = True
myRegExp.Global = True
myRegExp.Pattern =  "</a>((.|\n)*)"

Set myMatches = myRegExp.Execute(a)
For Each myMatch in myMatches
  response.write "MATCH: "
  response.write server.htmlencode(myMatch.submatches(0)) & "<br>"
Next

myRegExp.Pattern =  "</a>((.|\n)*?)</a>((.|\n)*)"

Set myMatches = myRegExp.Execute(a)
For Each myMatch in myMatches
  response.write "MATCH: "
  response.write server.htmlencode(myMatch.submatches(2)) & "<br>"
Next

%>

Tusind, tusind tak!

Kan jeg få dig til hurtigt at forklare mig hvad de enkelte linjer i koden gør? Det vil være en stor hjælp til at jeg selv kan forstå hvordan RegExp fungerer.

Tak igen...

Nej, det har jeg ikke kræfter til.

Fair nok.. tak for hjælpen

svar

Men hvis du kan spørge til noget specifikt, vil jeg gerne prøve at hjælpe dig med at forstå. Jeg kan bare ikke begynde at skrive en ny lærebog i regulære udtryk ;)

Det lyder super! Værdsætter det meget.

Det som forvirrer, er nok:

myRegExp.Pattern =  "</a>((.|\n)*)"

Hvad betyder tegnende som står efter "</a>"?


samt

myRegExp.Global = True

Hvad gør denne linje?

Når "global" er true finder den mere end den første forekomst. Det er vist lige meget her.

I regulære udtryk er der almindelige tegn, og "magiske" tegn.

De almindelige tegn betyder hvad de er:

  </a>

De magiske tegn:

  ((.|\n)*)

skal forklares.

  .|\n

betyder "et vilkårligt tegn ELLER linieskift"

  (noget)*

betyder at "noget" kan forekomme 0 eller flere gange. Og parenteser fungerer som parenteser plejer, plus at man kan aflæse i submatches hvad en given parentes indeholder.

Så det der står i </a>((.|\n)*) er blot at vi leder efter det første </a> og tager alt hvad der står bagefter, og kan finde det sidste i submatch nummer 0

Du har virkelig været en kæmpe hjælp for mig - tak tak tak.

Måske du kan hjælpe mig med en sidste ting...

Hvis nu at jeg ønsker at gøre det omvendt, således at jeg får udskrevet alt hvad der er INDEN første </a> samt INDEN det andet </a>

Således at jeg får henholdsvis:

<table>
    <tr>
        <td><a id="abc12345">abc12345


og


<table>
    <tr>
        <td><a id="abc12345">abc12345</a><a id="bbb23456">bbb23456

Kører på http://asp.n0p.com/919872a.asp og indeholder nedenstående. En bemærkning er at regulære udtryk med et * eller + pr default er grådige, og forsøger at matche så meget som muligt. Men man får dem til at stoppe på første match ved at sætte et ? efter * eller +.

<%

a = "<table>" & vbcrlf &  _
    "<tr>" & vbcrlf & _
    "<td><a id=""abc12345"">abc12345</a><a id=""bbb23456"">bbb23456</a><a id=""ccc34567"">ccc34567</a></td>" & vbcrlf & _
    "</tr>" & vbcrlf & _
    "</table>"
   
response.write server.htmlencode(a)

response.write "<hr><br>"

Set myRegExp = New RegExp
myRegExp.IgnoreCase = True
myRegExp.Global = True
myRegExp.Pattern =  "^((.|\n)*?)</a>"

Set myMatches = myRegExp.Execute(a)
For Each myMatch in myMatches
  response.write "MATCH: "
  response.write server.htmlencode(myMatch.submatches(0)) & "<br>"
Next

myRegExp.Pattern =  "((.|\n)*?</a>(.|\n)*?)</a>"

Set myMatches = myRegExp.Execute(a)
For Each myMatch in myMatches
  response.write "MATCH: "
  response.write server.htmlencode(myMatch.submatches(0)) & "<br>"
Next

%>