Konvatere over til en mssql db

Man kan godt have en Access applikation som henter data fra en SQLServer database.

Det er endda meget almindeligt.

Men det kan maaske godt kraeve nogle aendringer i app. Specielt hvis den er meget gammel.

Det er en acces 2003 den køre på.
Hvordan skifter man så nemmest over så den kører på mssql istedet for?

upsize wizard

http://office.microsoft.com/en-us/access-help/use-the-upsizing-wizard-HP005273009.aspx

Inden du gør det, så sørg som minimum for at du har et autogeneret id nr som primær nøgle i alle tabeller. Derefter skal du have de relevante id numre ind i alle forespørgsler, som skal være opdaterbare.

Når du så har upsized, så connecter du således:

Function AttachDSNLessTable(stLocalTableName As String, stRemoteTableName As String, stServer As String, stDatabase As String, Optional stUsername As String, Optional stPassword As String)
    On Error GoTo AttachDSNLessTable_Err
    Dim td As TableDef
    Dim stConnect As String
   
    For Each td In CurrentDb.TableDefs
        If td.Name = stLocalTableName Then
            CurrentDb.TableDefs.Delete stLocalTableName
        End If
    Next
     
    If Len(stUsername) = 0 Then
        '//Use trusted authentication if stUsername is not supplied.
        stConnect = "ODBC;DRIVER=SQL Server;SERVER=" & stServer & ";DATABASE=" & stDatabase & ";Trusted_Connection=Yes"
    Else
        '//WARNING: This will save the username and the password with the linked table information.
        stConnect = "ODBC;DRIVER=SQL Server;SERVER=" & stServer & ";DATABASE=" & stDatabase & ";UID=" & stUsername & ";PWD=" & stPassword
    End If
    Set td = CurrentDb.CreateTableDef(stLocalTableName, dbAttachSavePWD, stRemoteTableName, stConnect)
    CurrentDb.TableDefs.Append td
    AttachDSNLessTable = True
    Exit Function

AttachDSNLessTable_Err:
   
    AttachDSNLessTable = False
    MsgBox "AttachDSNLessTable encountered an unexpected error: " & Err.Description

End Function

Public Function ConnectAll()
Call AttachDSNLessTable("TabelNavnAccessDb", "dbo.tabelNavnSqlServer", "Servernavn eller ip", "SqlDatabaseNavn", "SqlDbBrugernavn", "SqlDbPassword")
End Function

..som du nok bemærker, så skal der oprettes en bruger med de relevante rettigheder til din db på SQL serveren!~)

Tid at få afsluttet her?