Makro: Søg og erstat i dokument - både i tekst, sidehoved og sidefod

Ja, det er muligt. Et dokument består af en masse "StoryRanges", og makroen skal søge igennem dem alle. Du finder en sådan makroløsning her (se Step 3 hvis du skal have den vandtætte løsning, men Step 2 kan måske gøre det i din situation):
http://word.mvps.org/faqs/customization/ReplaceAnywhere.htm

Hej,

Jeg har nu fået den til at finde alt i dokumentet ved hjælp at linket ovenfor. Jeg kan dog kun få den til det nå
r jeg har én (1) txt.value. Hvordan gør jeg så jeg kan "søg og erstat" når jeg har flere txt.value?

På forhånd tak.



Private Sub cmdOK_Click()

FrmformularDK.Hide

    ChangeFileOpenDirectory Makroer.StiSkabKontrakter
        Documents.Add Template:="formularDK.dotx"

Dim A
    A = Txtfirma.Value
   
 
Dim rngStory As Word.Range

  Dim lngJunk As Long


  lngJunk = ActiveDocument.Sections(1).Headers(1).Range.StoryType

  For Each rngStory In ActiveDocument.StoryRanges

    Do

      With rngStory.Find

 
        .Text = "[Selskabets navn]"
        .Replacement.Text = A
                 
        .Wrap = wdFindContinue

        .Execute Replace:=wdReplaceAll

      End With

 
      Set rngStory = rngStory.NextStoryRange

    Loop Until rngStory Is Nothing

  Next

End Sub

Så kan du bygge en løkke ind, som får erstatningen til at køre flere gange, f.eks. sådan (se kommentarerne i koden):

Private Sub cmdOK_Click()

    FrmformularDK.Hide

    ChangeFileOpenDirectory Makroer.StiSkabKontrakter
    Documents.Add Template:="formularDK.dotx"

    Dim A
   
    A = Txtfirma.value

    Dim rngStory As Word.Range
    Dim lngJunk As Long
    Dim oArray As Variant 'til definition af tekster, der skal findes
    Dim n As Long
   
    'Udskift teksterne i arrayet med de ønskede søgestrenge - føj flere til eller fjern efter behov
    oArray = Array("tekst1", "tekst2", "tekst3")

   
    'Gentag koden nedenfor for alle værdier i oArray
    For n = LBound(oArray) To UBound(oArray)
        lngJunk = ActiveDocument.Sections(1).Headers(1).Range.StoryType
   
        For Each rngStory In ActiveDocument.StoryRanges
   
            Do
                With rngStory.Find
                    .Text = oArray(n) 'teksten, der skal findes
                    .Replacement.Text = A
                    .Wrap = wdFindContinue
                    .Execute Replace:=wdReplaceAll
                End With
   
                Set rngStory = rngStory.NextStoryRange
   
            Loop Until rngStory Is Nothing
   
        Next
    Next n

End Sub

Mange tak for hjælpen. Det virker perfekt - dog tager det lidt tid at køre med alle de loop.

Smider du lige et svar.

Anders

Velbekomme.