Test om besøgende er smartphone

Det er HTTP_USER_AGENT du skal have fat i.
Forsøgte på min egen side med min telefon, kunne der læse dette i loggen:

"Nokia5310XpressMusic/2.0 (05.81) Profile/MIDP-2.1 Configuration/CLDC-1.1"

Prøv denne søgestreng:
http://www.eksperten.dk/search?category=3&q=HTTP_USER_AGENT

Jeg bruger selv:

<%
'Mobil detection
Dim user_agent, mobile_browser, Regex, match, mobile_agents, mobile_ua, ia, size

user_agent = Request.ServerVariables("HTTP_USER_AGENT")

mobile_browser = 0

Set Regex = New RegExp
With Regex
  .Pattern = "(up.browser|up.link|mmp|symbian|smartphone|midp|wap|phone|windows ce|pda|mobile|mini|palm)"
  .IgnoreCase = True
  .Global = True
End With

match = Regex.Test(user_agent)

If match Then mobile_browser = mobile_browser+1

If InStr(Request.ServerVariables("HTTP_ACCEPT"), "application/vnd.wap.xhtml+xml") Or Not IsEmpty(Request.ServerVariables("HTTP_X_PROFILE")) Or Not IsEmpty(Request.ServerVariables("HTTP_PROFILE")) Then
  mobile_browser = mobile_browser+1
end If

mobile_agents = Array("w3c ", "acs-", "alav", "alca", "amoi", "audi", "avan", "benq", "bird", "blac", "blaz", "brew", "cell", "cldc", "cmd-", "dang", "doco", "eric", "hipt", "inno", "ipaq", "java", "jigs", "kddi", "keji", "leno", "lg-c", "lg-d", "lg-g", "lge-", "maui", "maxo", "midp", "mits", "mmef", "mobi", "mot-", "moto", "mwbp", "nec-", "newt", "noki", "operamini", "palm", "pana", "pant", "phil", "play", "port", "prox", "qwap", "sage", "sams", "sany", "sch-", "sec-", "send", "seri", "sgh-", "shar", "sie-", "siem", "smal", "smar", "sony", "sph-", "symb", "t-mo", "teli", "tim-", "tosh", "tsm-", "upg1", "upsi", "vk-v", "voda", "wap-", "wapa", "wapi", "wapp", "wapr", "webc", "winw", "winw", "xda", "xda-")

size = Ubound(mobile_agents)
mobile_ua = LCase(Left(user_agent, 4))

For ia=0 To size
  If mobile_agents(ia) = mobile_ua Then
      mobile_browser = mobile_browser+1
      Exit For
  End If
Next

If mobile_browser>0 Then
  Response.Write("Bruger af smartphone")
Else
  Response.Write("Bruger der IKKE anvender smartphone")
End If
%>

Kommet videre ?????

Jeg valgte at sorterer efter skærmstørrelse, det var på stedet lige det hurtigste, nok ikke nødvendigvis det rigtigste, men det virkede ok.

Jeg deler gerne pointne mellem jer, så vil i ikke sende et par svar.

Et svar, og takker.

også svar herfra :)