WebClient - Læs cookies

Jeg mener at du skal bruge (Http)WebRequest og CookieContainer i.s.f. WebClient.

Har ikke før arbejdet med HttpWebRequest eller CookieContainer, kunne du give et eksempel på, hvordan jeg med HttpWebRequest kan bruge POST method og derefter læse cookies?

Først et eksempel med GET:

Imports System
Imports System.IO
Imports System.Net

Namespace E
    Public Class Program
        Public Shared Sub Main(args As String())
            Dim req As HttpWebRequest = CType(WebRequest.Create("http://www.projo.com/"), HttpWebRequest)
            req.CookieContainer = New CookieContainer
            Dim resp As HttpWebResponse = CType(req.GetResponse, HttpWebResponse)
            For Each c As Cookie In req.CookieContainer.GetCookies(New Uri("http://www.projo.com/"))
                Console.WriteLine("name=" & c.Name & " value=" & c.Value & " expires=" & c.Expires)
            Next
            Dim sr As StreamReader = New StreamReader(resp.GetResponseStream())
            Dim content As String = sr.ReadToEnd
            Console.WriteLine(content)
            Console.ReadKey()
        End Sub
    End Class
End Namespace

Og så et med POST:

Imports System
Imports System.IO
Imports System.Net

Namespace E
    Public Class Program
        Public Shared Sub Main(args As String())
            Dim req As HttpWebRequest = CType(WebRequest.Create("http://arne/htbin/tell2"), HttpWebRequest)
            req.CookieContainer = New CookieContainer
            req.Method = "POST"
            req.ContentType = "application/x-www-form-urlencoded"
            Dim sw As StreamWriter = New StreamWriter(req.GetRequestStream())
            sw.Write("field1=value1&field2=value2")
            sw.Close()
            Dim resp As HttpWebResponse = CType(req.GetResponse, HttpWebResponse)
            For Each c As Cookie In req.CookieContainer.GetCookies(New Uri("http://arne/htbin/tell2"))
                Console.WriteLine("name=" & c.Name & " value=" & c.Value & " expires=" & c.Expires)
            Next
            Dim sr As StreamReader = New StreamReader(resp.GetResponseStream())
            Dim content As String = sr.ReadToEnd
            Console.WriteLine(content)
            Console.ReadKey()
        End Sub
    End Class
End Namespace

Tak - og så mangler vi bare et svar! :-)

kommer her