kolon delimited text

Er data formateret således hver linie indeholder én række, eller er det bare én lang linie med 5 værdier pr. række?

Hvis det er opdelt på linier, kan du starte med at splitte dit indhold ved linieskifte og for hver linie så splitte indholdet ved kolon. Split-funktionen i VBS returnerer et array af strenge hvori du så kan søge...

Hvis data ligger i én lang streng, skal du nok benytte en anden metode, men det afhænger af hvor stor datamængde du forventer. En Split kan godt bruges, så skal du bare selv håndtere rækkeindekseringen (dvs. sørge for at skifte række for hvert 5. element, hvilket nu heller ikke burde være et problem...).

Data kommer ind på række niveau Men der ca 60 kolloner (kolon) pr. række, hvor det ca. er en 1/4 af kollonerne jeg skal trække data ud fra... Vil det stadig være en god løsning at splitte den op på den måde eller er der noget smartere ??

ja, det er fint nok at splitte dem ved linieskiftet i første omgang og så pr. kolon i forbindelse med iterationen over alle rækkerne. Så det kunne blive noget i stil med dette:

arrLines = split(data, vbCrLf)
for each ln in arrLines
  arrCols = split(ln, ":")
  ' aflæs de kolonner du skal bruge, f.eks. arrCols(0) for første kolonne
  ' arrCols(1) for anden kolonne osv.
next

Jeg prøver at kigge på det i aften :-)

Jeg kunne ikke få dit eks. til at virke...

Jeg får en fejl:
Microsoft VBScript runtime error '800a0009'
Subscript out of range: '[number: 0]'
/test/default.asp, line 50

  set objSvrXML2 = Server.CreateObject("MSXML2.ServerXMLHTTP.3.0")
  objSvrXML2.open "GET", url, false
  objSvrXML2.send
  indhold = objSvrXML2.responseText

output = ""
arr = split(indhold, vbCrLf)
inTheZone = false
for each ln in arr
  if left(trim(ln),1) <> ";" then
    if trim(ln) = "!CLIENTS:" then
      inTheZone = true
    elseif trim(ln) = "!SERVERS:" then
      inTheZone = false
    elseif inTheZone then
      output = output & ln & vbCrLf
    end if
  end if
next

Data = ""
response.write("<textarea name=vsData wrap=off cols=100 rows=20>"&output&"</textarea><br><br>")

VData = output ' request.form("vsdata")
arrLines = split(VData, vbCrLf)
for each ln in arrLines
  arrCols = split(ln, ":")
  ' aflæs de kolonner du skal bruge, f.eks. arrCols(0) for første kolonne
  ' arrCols(1) for anden kolonne osv.
data = data & arrCols(0) & vbCrLf
next

response.write("<textarea name=vData wrap=off cols=100 rows=20>"&data&"</textarea><br><br>")

Der kommer fint data ind da den første textarea bliver fyldt som den skal...

Nu ved jeg ikke lige hvilken linie der er 50, men jeg antager det er fordi der er en tom linie i det resultat du får hentet og at indekseringen arrCols(0) måske derfor bliver ugyldig.

Du kan evt. rette den sidste løkke til:

VData = output ' request.form("vsdata")
arrLines = split(VData, vbCrLf)
for each ln in arrLines
  arrCols = split(ln, ":")
  ' aflæs de kolonner du skal bruge, f.eks. arrCols(0) for første kolonne
  ' arrCols(1) for anden kolonne osv.
  if ubound(arrCols) > -1 then
    data = data & arrCols(0) & vbCrLf
  end if
next

Det var lige det der skulle til - Takker mange gange :-)
Lægger du et svar :-)

Velbekomme :-)

Tak for point :)