Find filer og mapper

Kig på FSO: File System Object: http://msdn.microsoft.com/en-us/library/hww8txat(VS.85).aspx

Måske bedre her: http://www.tutorial-web.com/asp/fso/

kender godt lidt brugen af FSO, og kan også godt få listet mapper og filer. Det er mere det med, at den først skal ind i en mappe, tjekker om der er billeder, derefter tjekke om der er undermapper, gå ind i dem osv. Og så skal den også gå tilbage i mappe strukturen og gøre det samme. Her står jeg nok lidt af.

Prøv evt. denne - den ser ud til at være rekursiv (dvs. at den kalder sig selv og bruger den metode til at hente alle undermapper/filer):

<% sub ListFolderContents(path)

    dim fs, folder, file, item, url

    set fs = CreateObject("Scripting.FileSystemObject")
    set folder = fs.GetFolder(path)

    'Display the target folder and info.

    Response.Write("<li><b>" & folder.Name & "</b> - " _
      & folder.Files.Count & " files, ")
    if folder.SubFolders.Count > 0 then
      Response.Write(folder.SubFolders.Count & " directories, ")
    end if
    Response.Write(Round(folder.Size / 1024) & " KB total." _
      & "</li>" & vbCrLf)

    Response.Write("<ul>" & vbCrLf)

    'Display a list of sub folders.

    for each item in folder.SubFolders
      ListFolderContents(item.Path)
    next

    'Display a list of files.

    for each item in folder.Files
      url = MapURL(item.path)
      Response.Write("<li><a href=""" & url & """>" _
        & item.Name & "</a> - " _
        & item.Size & " bytes, " _
        & "last modified on " & item.DateLastModified & "." _
        & "</li>" & vbCrLf)
    next

    Response.Write("</ul>" & vbCrLf)

  end sub %>

w13 -> Perfekt, det var lige det jeg havde brug for. Tak

Lyder godt. =)

Her er et svar så!

Tak for points!