For each sheet..

Nu skriver du ikke, hvad der ikke virker. Når jeg kører din kode, virker den upåklageligt, så kan du ikke forklare lidt nærmere?

Koden kan diog skæres ned til:

Dim ws As Worksheet

For Each ws In Worksheets
    ws.Cells.Copy
    ws.Cells.PasteSpecial Paste:=xlPasteValues
    ws.Cells.ClearComments
Next ws

Du bruger jo alligevel ikke tælleren til noget.

Jeg får fejlen:

Run-time error '-2147417847 (80010108)':
Method 'PasteSpecial' of object 'Range' failed

Er nogle af dine ark beskyttede?

Nej det er der ikke.
Fandt dog lige ud af at, når jeg gemmer efter fejlen og kører makroen igen.
Så virker det. Men ikke første gang.

Kan det tænkes at der er noget overload fejl i det?

Det er muligt, men i givet fald forstår jeg ikke hvorfor. Du kopiere alle celler, og indsætter dem derefter igen. Har du prøvet kun at kopiere relevante celler, og så indsætte disse igen?

Det svinger utrolig meget fra ark til ark, så har jeg ikke lyst til.
Mener heller ikke det er den rette løsning.

Hvordan er det nu med copy/indsæt funktionen, ændrer den sig i forhold til om det er range/graf'er/objekts/figurer man arbejder med?

Ikke så vidt jeg husker, men alt, hvad der kopieres, skal jo gemmes i RAM, og derefter indsættes. Så hvis der er mange data i de enkelte ark, kan dette måske forårsage problemet.

Kan man evt. clear sin clipboard?

For Each ws In Worksheets
    ws.Cells.Copy
    ws.Cells.PasteSpecial Paste:=xlPasteValues
Clear.Clipboard....???
    ws.Cells.ClearComments
Next ws

Det må man kunne, men da clipboardet styres af Windows ikke af Excel, skal man nok have fat i en Windowskommando, og den har jeg ikke lige present.

Application.CutCopyMode = False

Burde være nok, hvis ikke så prøv;

Private Declare Function EmptyClipboard Lib "user32" () As Long
Private Declare Function CloseClipboard Lib "user32" () As Long
Private Declare Function OpenClipboard Lib "user32" (ByVal hWnd As Long) As Long
Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Sub EmptyCB()
Dim hWnd As Long
    hWnd = FindWindow("XLMAIN", Application.Caption)
    OpenClipboard hWnd
    EmptyClipboard
    CloseClipboard
End Sub

Jeg må helt ærlig give op på denne.
Kommer ikke uden om fejlen:

Run-time error '-2147417847 (80010108)':
Method 'PasteSpecial' of object 'Range' failed

Hvis jeg lukker excel med task manager efter denne fejl, så skriver den at jeg ikke kunne udfører jobbet med de tilgængelige resurcer.

Så det er simpelthen en fejl i mængden af dataen.

Det har du nok ret i.

Jeg løste det med følgende kode:

Sub PublishReport()
    Dim ws As Worksheet
    Dim strFileName As String
   
    Application.ScreenUpdating = False
   
    strFileName = ActiveWorkbook.Path & "\Reports\" & Format(Now(), "yyyy-mm-dd") & ".xls"
   
    Worksheets().Copy

    Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs Filename:=strFileName, FileFormat:=xlNormal, Password:="", WriteResPassword:="", ReadOnlyRecommended:=False, CreateBackup:=False
 
    ActiveWorkbook.BreakLink Name:= _
        "DIR, FIL", _
        Type:=xlExcelLinks
   
    For Each ws In Worksheets
        ws.EnableSelection = xlNoRestrictions
        ws.Protect Contents:=True, UserInterFaceOnly:=False
    Next ws
   
    ActiveWorkbook.Protect Structure:=True, Windows:=False
   
    ActiveWorkbook.Sheets("Front Page").Select
   
    ActiveWorkbook.SaveAs Filename:=strFileName, FileFormat:=xlNormal, Password:="", WriteResPassword:="", ReadOnlyRecommended:=False, CreateBackup:=False
     
     
    Application.DisplayAlerts = True
    ActiveWorkbook.Close
   
    Application.ScreenUpdating = True
End Sub