Update hvis findes ellers Insert

Noget med:

' tjek først om der findes en række med dne pågældende email
sql = "SELECT COUNT(*) FROM tabel WHERE email = ?"
set cmd = Server.CreateObject("ADODB.Command")
set cmd.ActiveConnection = dit_connectionobjekt
cmd.Parameters.Append cmd.CreateParameter("@email", adVarChar, adParamInput, 255, email)
set rs = cmd.Execute()
doInsert = (clng(rs(0)) = 0)
rs.close
set rs = nothing

' Udfør derefter indsæt eller opdater alt efter udfaldet af ovenstående tjek.
set cmd = Server.CreateObject("ADODB.Command")
set cmd.ActiveConnection = dit_connectionobjekt

if doInsert then
  sql = "INSERT INTO tabel(navn,email,antal,dato) VALUES(?,?,1,now)"
  cmd.Parameters.Append cmd.CreateParameter("@navn", adVarChar, adParamInput, 255, navn)
  cmd.Parameters.Append cmd.CreateParameter("@email", adVarChar, adParamInput, 255, email)
else
  sql = "UPDATE tabel SET antal = antal + 1 WHERE email = ?"
  cmd.Parameters.Append cmd.CreateParameter("@email", adVarChar, adParamInput, 255, email)
end if

cmd.Execute


For at dette skal fungere, skal du have denne linie ind i enten global.asa (så skal du ikke tænke på den mere) eller i den fil hvor du benytter ADO-konstanter:

<!-- METADATA TYPE="typelib" uuid="00000205-0000-0010-8000-00AA006D2EA4"  -->

Ups! Jeg mangler lidt at tildele sql-sætningen til command-objektet - soorwy!

' tjek først om der findes en række med dne pågældende email
sql = "SELECT COUNT(*) FROM tabel WHERE email = ?"
set cmd = Server.CreateObject("ADODB.Command")
set cmd.ActiveConnection = dit_connectionobjekt
cmd.CommandText = sql
cmd.CommandType = adCmdText
cmd.Parameters.Append cmd.CreateParameter("@email", adVarChar, adParamInput, 255, email)
set rs = cmd.Execute()
doInsert = (clng(rs(0)) = 0)
rs.close
set rs = nothing

' Udfør derefter indsæt eller opdater alt efter udfaldet af ovenstående tjek.
set cmd = Server.CreateObject("ADODB.Command")
set cmd.ActiveConnection = dit_connectionobjekt
cmd.CommandType = adCmdText

if doInsert then
  sql = "INSERT INTO tabel(navn,email,antal,dato) VALUES(?,?,1,now)"
  cmd.CommandText = sql
  cmd.Parameters.Append cmd.CreateParameter("@navn", adVarChar, adParamInput, 255, navn)
  cmd.Parameters.Append cmd.CreateParameter("@email", adVarChar, adParamInput, 255, email)
else
  sql = "UPDATE tabel SET antal = antal + 1 WHERE email = ?"
  cmd.CommandText = sql
  cmd.Parameters.Append cmd.CreateParameter("@email", adVarChar, adParamInput, 255, email)
end if
cmd.Execute

det er enklere blot at slette
og derefter lave insert.

delete from tabel where email = ?
insert into tabel (navn,email,antal,dato) VALUES(?,?,1,now)
commit

bauerdata >> da ikke hvis antallet skal opdateres for eksisterende!?

Okey
så er det lettere at prøve update først
hvis den fejler
så lav en insert.