Ændre combobox2 automatisk i userform efter valgtet at combobox1

Kan du ikke oprette noget kode på event niveau ?
onchange eller onselect eller lign ?

Det vil jeg tro, men jeg er ikke helt med på hvordan koden ser ud.

Jeg formoder vi snakker VBA i Word ikke ?

jo det var det jeg regnede med.
En eller anden form for kode som skal ligge under "userformen"

Det må være noget i stil med:

Private Sub ComboBox1_Change()
  ActiveDocument.FormFields("Text1").Result = ComboBox1.Value
End Sub

Det skal så bare ikke være Text1, men combobox2

Fandt en løsning som ser således ud

Private Sub combobox1_Change()
If combobox1.Value = "navn1" Then
combobox2.Value = "titela"
End If
If combobox1.Value = "navn2" Then
combobox2.Value = "titelb"
End If
' osv
End Sub

Du kunne måske overveje at smide dine navn1 og titela osv... i et array og så bruge det videre.
Det er måske lidt mere elegant.
Men du får et svar.

Mange tak for hjælpen.
det med array er for kompliceret til mig, men hvis du har et bud vil jeg da gerne se hvordan det kan gøres. :-)

Jeg kan sagtens se at min kode ikke er så elegant :-)

Jeg troede arrays var ligesom i php, hvor man kan bruge key og value.
Men kan ikke lige finde noget god doc på array og vba.
Så det må komme senere, hvis jeg lige falder over det. :o)

Og glemte helt, takker for point.

Et lille eksempel med en userform med to combobokse på eller en combobox og en textbox

'Læs mere om arrays her http://www.eksperten.dk/artikler/522
Dim mvntPersons(2, 1) As Variant

Private Sub ComboBox1_Change()
    With Me.ComboBox2
        .Clear
        .AddItem FindTitle(.Text)
    End With
    'Hvis der altid kun er EN tekst i ComboBox1,
    'så ville jeg nok lave det til en TextBox i stedet,
    'og nøjes med denne ene linie heri
    'Me.TextBox1.Text = FindTitle(Me.ComboBox1.Text)
End Sub

Private Sub UserForm_Initialize()
    Dim iItem As Integer
   
    'Smid noget i dit array
    mvntPersons(0, 0) = "Navn 1"
    mvntPersons(0, 1) = "Title A"
    mvntPersons(1, 0) = "Navn 3"
    mvntPersons(1, 1) = "Title B"
    mvntPersons(2, 0) = "Navn 3"
    mvntPersons(2, 1) = "Title C"
   
    'Smid Navn i ComboBox1
    For iItem = 0 To UBound(mvntPersons, 1)
        Me.ComboBox1.AddItem mvntPersons(iItem, 0)
    Next iItem
End Sub

Public Function FindTitle(ByVal sName As String) As String
    Dim sRetVal As String
    Dim iItem As Integer
   
    For iItem = 0 To UBound(mvntPersons, 1)
        If mvntPersons(iItem, 0) = sName Then
            sRetVal = mvntPersons(iItem, 0)
            Exit For
        End If
    Next iItem
   
    FindTitle = sRetVal
End Function

Ahh - jeg skulle have testet først :-) denne her virker

'Læs mere om arrays her http://www.eksperten.dk/artikler/522
Dim mvntPersons(2, 1) As Variant

Private Sub ComboBox1_Change()
    With Me.ComboBox2
        .Clear
        .AddItem FindTitle(Me.ComboBox1.Text)
    End With
    'Hvis der altid kun er EN tekst i ComboBox1,
    'så ville jeg nok lave det til en TextBox i stedet,
    'og nøjes med denne ene linie heri
    'Me.TextBox1.Text = FindTitle(Me.ComboBox1.Text)
End Sub

Private Sub UserForm_Initialize()
    Dim iItem As Integer
   
    'Smid noget i dit array
    mvntPersons(0, 0) = "Navn 1"
    mvntPersons(0, 1) = "Title A"
    mvntPersons(1, 0) = "Navn 2"
    mvntPersons(1, 1) = "Title B"
    mvntPersons(2, 0) = "Navn 3"
    mvntPersons(2, 1) = "Title C"
   
    'Smid Navn i ComboBox1
    For iItem = 0 To UBound(mvntPersons, 1)
        Me.ComboBox1.AddItem mvntPersons(iItem, 0)
    Next iItem
End Sub

Public Function FindTitle(ByVal sName As String) As String
    Dim sRetVal As String
    Dim iItem As Integer
   
    For iItem = 0 To UBound(mvntPersons, 1)
        If mvntPersons(iItem, 0) = sName Then
            sRetVal = mvntPersons(iItem, 1)
            Exit For
        End If
    Next iItem
   
    FindTitle = sRetVal
End Function