tjek tegn i streng

Functionen InStr checker om HELE strengen ValidChar ("_:/.-") er indeholdt inputstr,
fra char i, og længden 1.
dette vil aldrig blive true, derfor vil den aldrig melde fejl.

Du kan tage een karakter ad gangen fra ValidCher og scecke om den er indeholdt i inputstr.
På'en igen !

Ja, det skal nok undersøges således:

Function CheckInput(inputstr)
  dim validChar, i
  validChar = "_:/.-,abcdefghijklmnopqrstuvwxyzæøå0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZÆØÅ"
  for i = 1 to len(inputstr)
    if inStr(1, validChar, Mid(inputstr, i, 1)) = 0 then
      ' tegnet findes ikke i validChar, så derfor returneres false
      CheckInput = false
      exit function
    end if
  next
  CheckInput = true
end function

tjek = "http://www.ditdomæne.dk/test.asp"
if CheckInput(tjek) = true then
  response.write "ok"
else
  response.write "fejl"
end if


Alternativt kunne du evt. benytte regulære udtryk (den er nok noget hurtigere end den iteration du selv har foreslået):

Function CheckInput(inputstr)
  dim rx
  set rx = new RegExp
  rx.global = true
  rx.ignorecase = true
  rx.pattern = "^[\_\:\/\.\-\,abcdefghijklmnopqrstuvwxyzæøå0123456789]+$"
  CheckInput = rx.Test(inputstr)
  set rx = nothing
end function

tak for hjælpen - læg et svar

ja, det var ikke mig selv der skulle lægge et svar ;-))))

Velbekomme :)

så er det klaret - takker.

Tak for point :)