Dynamisk opbygning af SELECT?

Kan du ikke lave et dump af strukturen i din DB??
Så tror jeg bedre jeg kan hitte ud af det...

ITEMS:
CREATE TABLE IF NOT EXISTS `items` (
  `ID` int(11) NOT NULL auto_increment,
  `ipadresse` varchar(50) collate latin1_danish_ci default NULL,
`katid` int(11) NOT NULL ,
  `overskrift` varchar(50) collate latin1_danish_ci default NULL,
  `tekst` text collate latin1_danish_ci,
  `avistekst` text collate latin1_danish_ci NOT NULL,
  UNIQUE KEY `ID` (`ID`),
  ENGINE=MyISAM  DEFAULT CHARSET=latin1 COLLATE=latin1_danish_ci AUTO_INCREMENT=37529 ;

KATEGORIER
CREATE TABLE IF NOT EXISTS `Kategorier` (
  `id` int(11) NOT NULL auto_increment,
  `parentid` int(3) NOT NULL,
  `kategori` varchar(50) collate latin1_danish_ci NOT NULL,
  PRIMARY KEY  (`id`)
) ENGINE=MyISAM  DEFAULT CHARSET=latin1 COLLATE=latin1_danish_ci AUTO_INCREMENT=67 ;

Var det det du mente?

Det er en MySQL DB

Lige uden at have testet det tror jeg noget lignende dette kunne bruges:

Dim intKatID, strSQL

intKatID = "2" '//Eller det tal der nu skal søges efter!

Set rsKats    =    Conn.Execute("SELECT * FROM `Kategorier` WHERE `parentid` = '" & intKatID  & "'"

'// Opbygning af SQL-streng
strSQL = "SELECT * FROM items WHERE (katid = " & intKatID

If Not rsKats.EOF Or rsKats.BOF Then
    Do
        strSQL = strSQL & " OR katid = " & rsKats("id")
    rsKats.MoveNext
    Loop While Not rsKats.EOF
End If

strSQL = strSQL & ")"

'// Execute på items-tabel
Set rsItems    =    Conn.Execute(strSQL)

Hejsa
Tak for kommentaren. Men det tager "vel kun" første niveau, hvad nu hvis en underkategori har underkategorier?

Hvis jeg kommer med katid = 2, skal resultatet blive: SELECT * FROM items WHERE (katid = 2 OR katid = 3 OR katid = 4 OR katid = 5 OR katid = 6)

Men ovenstående eksempel misser vi katid = 6, og resultatet bliver: SELECT * FROM items WHERE (katid = 2 OR katid = 3 OR katid = 4 OR katid = 5)

Jeg kender jo ikke hvor dybt min kategorisering går, derfor skal det laves dynamisk til et ukendt antal niveauer

Jeg må lave noget med et rekursivt kald, jeg tror jeg har fået en løsning tænkt frem gennem de sidste 24 timer :). Jeg vender lige tilbage

Så fik jeg lavet en lille funktion der kan give mig alle ID på en kategories underpunkter i n niveauer. Listen brugerne jeg så til at danne SQL'en med senere

Til dem der måtte have gavn af det, så er funktionen her:

strIDList = getIDListForSubCategories(2, 1, 1)

Function getIDListForSubCategories(strKatIDs, blnRecoursiv, blnReturnStartValue)
    'Find ID på alle de underkategorier den eller de medsendte kategori har
   
    strTempIDList = ""
    strFinalIDList = ""   
   
    'Split den medsendte streng i ID'erog løb dem igennem
    arrayOfIDs = split(strKatIDs,",")
    for i = 0 to ubound(arrayOfIDs)
        'Select alle de kategorier der er underkategori til den aktuelle kategori
        strSQL = "SELECT * FROM kategorier WHERE parentid = " & arrayOfIDs(i) & ""
        Set rsKats = Conn.Execute(strSQL)
       
        'Gem den fundne, men tjek først om startværdien skal returneres
        if blnReturnStartValue = 1 then
            if strFinalIDList <> "" then
                strFinalIDList = strFinalIDList & "," & arrayOfIDs(i)
            else
                strFinalIDList = arrayOfIDs(i)
            end if
        end if
       
        'Opsammel ID på underkategorierne, så vi kan tjekke om de har underkategorier
        If Not rsKats.EOF Or rsKats.BOF Then
            Do until rsKats.EOF
                if strTempIDList <> "" then
                    strTempIDList = strTempIDList & "," & rsKats("id")
                else
                    strTempIDList = rsKats("id")
                end if
                rsKats.MoveNext
            Loop           
        End if
    next
    if blnRecoursiv = 1 then
        if strTempIDList <> "" then
            'Kald igen med underkategorierne for at få deres underkategorier
            strFinalIDList = strFinalIDList & "," & getIDListForSubCategories(strTempIDList,blnRecoursiv,1)
        end if       
    else
        strFinalIDList = strTempIDList
    end if
    getIDListForSubCategories = strFinalIDList
End Function

bondester:
Smid et svar så deler vi, jeg bruger en del af det du skrev til efterfølgende at lave SQL'en

Nååå ja havde ikke lige tænkt på underpunkterne....
Håber dukunne bruge noget af det ;-)

Tak