Felter, hvor kolonnen er fast, men rækken bliver højere!

Hej Tanjamus

Cellerne du har flettet skal også have ombrydning af tekst slået til.

Højreklik på arkets fane og vælg View Code (eller hvad et nu hedder din version), og Indsæt følgende kode

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim NewRwHt As Single
    Dim cWdth As Single, MrgeWdth As Single
    Dim c As Range, cc As Range
    Dim ma As Range
    Dim ProtectStatus As Boolean

    With Target
        If .MergeCells And .WrapText Then
            ProtectStatus = Me.ProtectContents
            If ProtectStatus Then Me.Unprotect ' "password"
            Set c = Target.Cells(1, 1)
            cWdth = c.ColumnWidth
            Set ma = c.MergeArea
            For Each cc In ma.Cells
                MrgeWdth = MrgeWdth + cc.ColumnWidth
            Next
            Application.ScreenUpdating = False
            On Error Resume Next
            ma.MergeCells = False
            c.ColumnWidth = MrgeWdth
            c.EntireRow.AutoFit
            NewRwHt = c.RowHeight
            c.ColumnWidth = cWdth
            ma.MergeCells = True
            ma.RowHeight = NewRwHt
            cWdth = 0: MrgeWdth = 0
            On Error GoTo 0
            Application.ScreenUpdating = True
            If ProtectStatus Then Me.Protect ' "password"
        End If
    End With
End Sub

Det virker!

Tusind, tusind tak for hurtig hjælp!

Hvorfor vil den ikke godkende min acceptering af svaret?

Hmm - du skal klikke på mit brugernavn, så det bliver markeret, og så trykke accepter

Sådan! Endnu engang tusind tak!