aktiveringskode fra ikke-kørende xp installation

Hvor langt når du når du starter PC´eren op?
Har du prøvet at bruge F8 under opstart?

prøv at downloade Aida32 - der bør du kunne se licensnøglen
http://www.hcma.dk/uploads1/div_uploads.htm

Ellers er der en fil her som kan.
http://www.magicaljellybean.com/keyfinder.shtml

Hvis du ikke kan starte XP op kan du godt glemme at finde din licens nøgle, du må starte med at få systemet til at starte op, mere indformation, kan være at vi kan få XP til at boote op.

Hvis den gamle installation er så intakt, at man kan kigge i dens registreringsdatabase med regedit (fra den nye installation), så kan man godt trække nøglen ud, uden at skulle starte den gamle op

Respons fra spørger?

Jeg har ikke knækket opgaven endnu, så langt jeg er kommet er der ikke nogen af programmerne (magicaljellybean keyfinder, aida32 eller andre) der har evnen til at pille aktiveringskode eller licensnummer ud af en ikke-kørende installation.

Harddisken havde mange bad sectors (startede hverken i fejlsikret eller andet), i første omgang var den manglende fil pci.sys stopklodsen.

PT kommer jeg frem til login skærmen, men uden funktion på keyboard eller mus.

Planen er lige nu at søge at reetablere indholdet af systemmapperne ved at hente filerne fra en ren installation (den metode jeg brugte ved pci.sys).

Men hvis der er nogen der har en fidus der kan hente koden (den er købt hos ms gennem en lovliggjort xp pro installation og findes dermed kun på harddisken) ud af en ikke-fungerende installation vil jeg være taknemmelig.

Se hvad jeg skrev 09/03-2008 06:46:15 det holder stadig

silbidor: det er og den erkendelse jeg er nået til :-(

tak alle sammen

hvis der er interesse for at lege lidt med regedit, så er det i høj grad muligt uden at starte den gamle installation op

Hvis nogen ved percis hvor nøglen ligger, kan den måske ses ved hjælp af "Dappix"
En Linux, som køres direkte fra CD drevet, og som kan se windows.
http://tyge.sslug.dk/knoppix/

Processen kan næsten automatiseres, i to filer:

------------------------------------------------
getkey.bat:

@echo off
set gammmel_installation="e:\windows\system32\config\software"

If exist %gammmel_installation% (
  reg load hklm\old %gammmel_installation%
  cscript getkey.vbs
  reg unload hklm\old
) else (
  echo Kan ikke finde den gamle installation 
)
pause

------------------------------------------------
getkey.vbs:

Set objShell = CreateObject("WScript.Shell")

bDigitalProductID = objShell.RegRead("HKEY_LOCAL_MACHINE\old\Microsoft\Windows NT\CurrentVersion\DigitalProductID")
WScript.Echo "Nøglen er: " & GetXPCDKey(bDigitalProductID)

Public Function GetXPCDKey(bDigitalProductID)
    Dim bProductKey()
    Dim ilByte
    Dim nCur
    Dim sCDKey
    Dim ilKeyByte
    Dim ilBit

    ReDim Preserve bProductKey(14)

    For ilByte = 52 To 66
        bProductKey(ilByte - 52) = bDigitalProductID(ilByte)
    Next

    KeyChars = "BCDFGHJKMPQRTVWXY2346789"

    For ilByte = 24 To 0 Step -1
        nCur = 0
       
        For ilKeyByte = 14 To 0 Step -1
            nCur = nCur * 256 Xor bProductKey(ilKeyByte)
            bProductKey(ilKeyByte) = Int(nCur / 24)
            nCur = nCur Mod 24
        Next
       
        sCDKey = Mid(KeyChars, nCur+1, 1) & sCDKey
       
        If ilByte Mod 5 = 0 And ilByte <> 0 Then sCDKey = "-" & sCDKey
    Next

    GetXPCDKey = sCDKey
End Function

Tak til smitten1, det ser smukt ud. Tilbagemelding med resultatet i morgen :-)

hovsa, jeg er ikke så vandt til systemet her, så jeg kom til at give mig selv pointene. Jeg retter op på fejlen, og overfører dine point, smitten1, når jeg finder ud af hvordan.

smitten1 - se her: http://www.eksperten.dk/spm/823304

nuber2 - Man skal lige vise, hvor man har lagt point:)

tak jorn_asveg

hvor finder jeg getkey.vbs

det er en fil du selv laver :-)

brug notepad eller en bedre editor, sæt teksten fra smitten1 ind og gem filen som getkey.vbs ... på samme måde med getkey.bat.
anbring begge filer i samme mappe og kør getkey.bat


Indholdet af getkey.vbs

Set objShell = CreateObject("WScript.Shell")

bDigitalProductID = objShell.RegRead("HKEY_LOCAL_MACHINE\old\Microsoft\Windows NT\CurrentVersion\DigitalProductID")
WScript.Echo "Nøglen er: " & GetXPCDKey(bDigitalProductID)

Public Function GetXPCDKey(bDigitalProductID)
    Dim bProductKey()
    Dim ilByte
    Dim nCur
    Dim sCDKey
    Dim ilKeyByte
    Dim ilBit

    ReDim Preserve bProductKey(14)

    For ilByte = 52 To 66
        bProductKey(ilByte - 52) = bDigitalProductID(ilByte)
    Next

    KeyChars = "BCDFGHJKMPQRTVWXY2346789"

    For ilByte = 24 To 0 Step -1
        nCur = 0
     
        For ilKeyByte = 14 To 0 Step -1
            nCur = nCur * 256 Xor bProductKey(ilKeyByte)
            bProductKey(ilKeyByte) = Int(nCur / 24)
            nCur = nCur Mod 24
        Next
     
        sCDKey = Mid(KeyChars, nCur+1, 1) & sCDKey
     
        If ilByte Mod 5 = 0 And ilByte <> 0 Then sCDKey = "-" & sCDKey
    Next

    GetXPCDKey = sCDKey
End Function