AutoNum som tæller antal udprintninger

Måske - hvor skal dokumentnr. placeres?

I sidehovedet.... og dokumentet kommer aldrig til at fylde mere end 1 side

I dokumentet er der indbygget en Userform m/følgende nedenstående kode. - hvis det ønskes kan dokumentet m/VBA fremsendes - send en mail til:
pb@supertekst-it.dk


Dim pNr, nrFlag As Boolean
Private Sub CommandButton1_Click()                  'Udskriv
    For antalP = 1 To Val(Me.TextBox1)
        pNr = pNr + 1                              'Tæl nr 1 op
   
        With ActiveDocument.ActiveWindow.View
            .Type = wdPrintView
            .SeekView = wdSeekCurrentPageHeader
        End With

Rem Slet gl. Nr
        Selection.EndKey Unit:=wdStory, Extend:=wdExtend
        Selection.Delete Unit:=wdCharacter, Count:=1
       
Rem Indsæt aktuelle
        Selection.TypeText Text:="Nr. " + CStr(pNr)
           
        Set myview = ActiveDocument.ActiveWindow.View
        myview.SeekView = wdSeekMainDocument
       
        ActiveDocument.PrintOut
    Next antalP
   
    Label2.Caption = CStr(pNr)
   
    ActiveDocument.Variables("printnr").Value = pNr
    ActiveDocument.Save
End Sub
Private Sub CommandButton2_Click()                  'Luk formularen
Dim sv
    If nrFlag = True Then
        sv = MsgBox("Dokument-nr. er ændret - vil du gemme dette?", vbYesNo)
        If sv = 6 Then
            ActiveDocument.Variables("printnr").Value = pNr
            ActiveDocument.Save
        End If
    End If
   
    Unload UserForm1
End Sub
Private Sub SpinButton1_spinUp()
    nrFlag = True
   
    pNr = pNr + 1
    Label2.Caption = CStr(pNr)
End Sub
Private Sub SpinButton1_spinDown()
    nrFlag = True
   
    If pNr - 1 >= 0 Then
        pNr = pNr - 1
        Label2.Caption = CStr(pNr)
    End If
End Sub
Private Sub UserForm_activate()
    nrFlag = False
   
    Me.TextBox1 = 1
    pNr = findAktuelleNr
    Label2.Caption = CStr(pNr)
End Sub
Private Function findAktuelleNr()
    With ActiveDocument
        If .Variables.Count > 0 Then
            findAktuelleNr = .Variables("printnr").Value
        Else
            .Variables.Add "printNr", "0"
            findAktuelleNr = "0"
        End If
    End With
End Function

Her er så et svar.