Fra XML til mysqldatabase

Du læser teksten ind i et XMLDOM dokument og fisker felterne ud med
GetElementsByTagName eller SelectSingleNode.

utestet:

Set doc = Server.CreateObject("Microsoft.XMLDOM")
doc.Async = False
doc.LoadXml(xmlstr)
recipient = doc.SelectSingleNode("//ROOT/RECIPIENT").Text
result = doc.SelectSingleNode("//ROOT/RESULTT").Text
processingtime = doc.SelectSingleNode("//ROOT/PROCESSINGTIME").Text

Jeg bruger denne kode for at få ovenstående svar tilbage hvordan få jeg indlæs det i din kode?

surl = "https://gw.comsms.dk/Sms/?msg=" & rs("tekst") & "&rec=" & rs("mobilnr") & "&sapid=xxx&password=xxxx&bc=0000&oadc=xxxxxxxx&route=General"
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
Set objXMLDOM = Server.CreateObject("Microsoft.XMLDOM")
objXMLDOM.async = false
Call objXMLHTTP.Open("GET", surl, False)
objXMLHTTP.Send

stadig aldeles utestet:

objXMLDOM.LoadXml(objXMLHTTP.Response)
recipient = objXMLDOM.SelectSingleNode("//ROOT/RECIPIENT").Text
result = objXMLDOM.SelectSingleNode("//ROOT/RESULTT").Text
processingtime = objXMLDOM.SelectSingleNode("//ROOT/PROCESSINGTIME").Text

Den gir: Object doesn't support this property or method: 'objXMLHTTP.Response'
Jeg prøvede at rette den til objXMLDOM.LoadXml(objXMLHTTP.ResponseXML) men den gir: Type mismatch: 'objXMLDOM.LoadXml'
og objXMLDOM.LoadXml(objXMLHTTP.Responsetext) gir: Object required: 'objXMLDOM.SelectSingleNode(...)'

jacand> Jeg vil foreslå, at du lige læser nogle artikler/guides om området..

F.eks.: "Server-Side XML in ASP" - http://www.15seconds.com/issue/990527.htm

Søgning på Google: http://www.google.com/search?q=asp+Microsoft.XMLDOM

thesurfer> Jeg har brugt det meste af eftermiddagen på at søge på exp og google. men jeg kan ikke lige finde noget der kan bruges til mit problem, enter er det hvis man henter en XML fil eller åbner den på serveren.
Den enste måde jeg har kunnet få noget tekst ud er ved otekst = objXMLHTTP.Responsetext, som ikke er særlig brugbar når det skal ind i en database :-)

hehe.. "enter er det hvis man henter en XML fil eller åbner den på serveren"

Hvad tror du at din kode gør..? :-)

Du kontakter jo "https://gw.comsms.dk" for at få "filen"..

Den returnerer jo netop "en fil" i form af en streng..

Det er samme kode/funktionalitet..

Læs lige http://www.15seconds.com/issue/990527.htm igennem..

Artiklen er lidt lang, fordi alle skal kunne være med fra starten..

Meningen med artiklen er ikke en hurtig løsning, men viden så man kan lære det..

Så det tager nok lidt tid at komme igennem den.. :-)

Følgende demo virker hos mig:

<%
url = "http://localhost/simulate.xml"
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
Call objXMLHTTP.Open("GET", url, False)
Call objXMLHTTP.Send()
xml = objXMLHTTP.ResponseText
Set objXMLDOM = Server.CreateObject("Microsoft.XMLDOM")
objXMLDOM.Async = false
objXMLDOM.LoadXml(xml)
recipient = objXMLDOM.SelectSingleNode("//ROOT/RECIPIENT").Text
result = objXMLDOM.SelectSingleNode("//ROOT/RESULT").Text
processingtime = objXMLDOM.SelectSingleNode("//ROOT/PROCESSINGTIME").Text
Response.Write("INSERT INTO t VALUES(" & recipient & ",'" & result & "'," & processingtime & ")")
%>

arne_v> Husk lige at fjerne objekterne igen (i omvendt rækkefølge af oprettelsen):

Set objXMLDOM = nothing
Set objXMLHTTP = nothing

<ole>

Arne >> Er der en speciel årsag til, du bruger XMLDOM-objektet - i stedet for at bruge XMLHTTP-objektets reponseXML direkte?

/mvh
</bole>

thesurfer>

Det er nok en god ide.

olebole>

Ikke specielt.

Jeg har sakset XML parse delen fra noget kode jeg havde på lager og flettet det
sammen med spørgers HTTP kode.

Med ResponseXml bliver det:

<%
url = "http://localhost/simulate.xml"
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
Call objXMLHTTP.Open("GET", url, False)
Call objXMLHTTP.Send()
Set objXMLDOM = objXMLHTTP.ResponseXml
recipient = objXMLDOM.SelectSingleNode("//ROOT/RECIPIENT").Text
result = objXMLDOM.SelectSingleNode("//ROOT/RESULT").Text
processingtime = objXMLDOM.SelectSingleNode("//ROOT/PROCESSINGTIME").Text
Response.Write("INSERT INTO t VALUES(" & recipient & ",'" & result & "'," & processingtime & ")")
Set objXMLDOM = Nothing
Set objXMLHTTP = Nothing
%>

arne_v>

Den første virker :-)
Den sidst giver: Object required: 'objXMLDOM.SelectSingleNode(...)'

laver du lige et svar?

svar

den sidste virker nu også hos mig

Det kan måske være fordi min server ikke har fået installeret alle de sidste opdateringer fra M$ endnu. jeg prøver lige det sidst når jeg har fået opdateret den helt.

Tusind tak for hjælen.