Billeder fylder helvedes meget efter de køres gennem mit program

Jeg svarede på et lignende spørgsmål for noget tid siden (http://www.eksperten.dk/spm/701071). Her er et udsnit af mit svar:

-----------------------------------------------

Det er compression, der er tale om. Som udgangspunkt laver .NET vist ingen compression, men med følgende kode kan du angive, i hvilken kvalitet JPG-billedet skal gemmes (og derved også filstørrelsen).

Disse to første rutiner skal placeres et sted i din kode (husk at importere namespacet System.Drawing.Imaging):


  Public Function FindEncoder(ByVal pImageFormat As ImageFormat) As ImageCodecInfo
    'Benyttes til en finde en encoder ud fra et givent format:
    Dim lCodecInfos() As ImageCodecInfo
    lCodecInfos = ImageCodecInfo.GetImageEncoders
    For Each lCodecInfo As ImageCodecInfo In lCodecInfos
      If lCodecInfo.FormatID = pImageFormat.Guid Then
        Return lCodecInfo
      End If
    Next
    Return Nothing
  End Function

  Public Sub SaveCompressedJPEG(ByVal pImage As Image, _
                                ByVal pFileName As String, _
                                ByVal pQuality As Int32)
    'Find JPEG-encoder:
    Dim lEncoder As ImageCodecInfo = FindEncoder(ImageFormat.Jpeg)
    'Tilføj quality-parameter:
    Dim lParams As EncoderParameters = New EncoderParameters(1)
    lParams.Param(0) = New EncoderParameter(Encoder.Quality, pQuality)
    'Gem billede til fil:
    pImage.Save(pFileName, lEncoder, lParams)
  End Sub


Herefter kan du nu skrive denne ene linie for at gemme et JPG-billede med en kvalitetsfaktor fra 1-100 (1 er laveste kvalitet, 100 er højeste kvalitet):


  SaveCompressedJPEG(objImage, "C:\billede.jpg", 50)


Håber det hjælper.

nice tusind tak :D Smid svar.

Svar :-)