ini filer

I din formcreate - du mangler at tildele Image1 det billede du henter fra INI filen.

Image1.Picture.LoadFromFile(MyString);

Husk også at rydde op efter dig i "Indstillinger1Click" i slutningen:

MyINI.Free;

men kan du give mig et eksempel på hvordan det skal gøres. jeg kan ikke lige finde vejen til at få det til et virke

Her er et eksempel - det virker hos mig.
 
Jeg har ændret i INI filen - med henblik på slåfejlene.



procedure TForm1.Button1Click(Sender: TObject);
var
  MyINI: TINIFile; // TINIFile objektet
  PathToINIFile: String;
begin
  PathToINIFile := IncludeTrailingBackslash(ExtractFilePath(ParamStr(0)))+'fa.ini';
  {Skab objektet}

  if OpenDialog1.Execute then
  try
    Image1.Picture.LoadFromFile(OpenDialog1.Filename);
    MyINI := TINIFile.Create(PathToINIFile);
    MyINI.WriteString('Baggrund', 'Baggrundsbillede',OpenDialog1.FileName);
    MyINI.Free;
  except
    on EInvalidGraphic do
      Image1.Picture.Graphic := nil;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  MyIni : TINIFile;
  mystring,PathToFile : String;
begin
  PathToFile := IncludeTrailingPathDelimiter(ExtractFilePath(ParamStr(0)));
  MyINI := TINIFile.Create(PathToFile+'fa.ini');
  MyString := MyINI.ReadString('baggrund', 'baggrundsbillede', PathToFile + 'default.jpg');
  Image1.Picture.LoadFromFile(MyString);
end;

Glemte lige ... jeg har også ændret den streng der gemmes i INI filen i min Button1Click - det er nu OpenDialog1.FileName - og den ændres kun hvis du klikker OK i OpenDialog - altså den er med i Try blokken.

Jeg har også lagt et 'default.jpg' ind i min mappe med programmet - således at der altid er et "standard" billede hvis der ikke er dannet nogen INI fil. Det er i stedet for 'Ikke fundet' strengen.

Har lige lavet et lille program der gør det du gerne vil have det til - på aller simpleste måde - og med fornuftige (hvis man ellers kan lide ... var det Ungarsk navngivningsnotation?) navne - og med konstanter. Åhh. ja. Du skal huske at frigive dine objekter igen (Kan ikke lade være med at moralisere).

unit FMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtDlgs, ExtCtrls, StdCtrls;

type
  TfrmMain = class(TForm)
    opdBackground: TOpenPictureDialog;
    iBackground: TImage;
    pMain: TPanel;
    btnSetImage: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure btnSetImageClick(Sender: TObject);
  private
    fPath : string;
    fBackground : string;
    procedure SetBackground;
  public
  end;

var
  frmMain: TfrmMain;

implementation

{$R *.dfm}

uses
  IniFiles;

const
  IniFile = 'fa.ini';
  IniSection = 'Baggrund';
  IniValue = 'Billede';

procedure TfrmMain.btnSetImageClick(Sender: TObject);
begin
  SetBackground;
end;

procedure TfrmMain.FormCreate(Sender: TObject);
begin
  fPath := IncludeTrailingPathDelimiter(ExtractFilePath(Application.ExeName));

  with TINIFile.Create(fPath+IniFile) do
    try
      fBackground := ReadString(IniSection,IniValue,'');
    finally
      Free;
    end;

  if fBackground = '' then
    iBackground.Picture.Graphic := nil
  else
    iBackground.Picture.LoadFromFile(fBackground);
end;

procedure TfrmMain.FormDestroy(Sender: TObject);
begin
  with TINIFile.Create(fPath+IniFile) do
    try
      WriteString(IniSection,IniValue,fBackground);
    finally
      Free;
    end;
end;

procedure TfrmMain.SetBackground;
begin
  opdBackground.Filename := fBackground;
  if opdBackground.Execute then
  begin
    fBackground := opdBackground.Filename;
    iBackground.Picture.LoadFromFile(fBackground);
  end;
end;

end.

Jeg får denne fejl... som en warning når jeg jeg trykker på built project i project menuen

[Pascal Warning] Unit2.pas(131): W1002 Symbol 'IncludeTrailingBackslash' is specific to a platform

Egentlig kan du bare ignorere den. I mit eksempel bruger jeg IncludeTrailingPathDelimiter der er platformuafhængig