Eksterne værdier hentet i Word - Dropdown

Du er velkommen til at sende den til: pb@supertekst-it.dk

Koden i den til skabelonen tilknyttede Userform:
Dim sti, antalUdlån
Private Sub testFelter()
    If Me.CelleNr <> "" And _
        Me.Navn <> "" And _
            Me.Cpr <> "" And _
                Me.MaskineNr <> "" And _
                    Me.AntalController <> "" Then
                    Me.ListBox1.Enabled = True
                    Me.CommandButton1.Enabled = True
    Else
        Me.ListBox1.Enabled = False
        Me.CommandButton1.Enabled = False
    End If
End Sub
Private Sub CelleNr_Change()
    testFelter
End Sub
Private Sub Navn_Change()
    testFelter
End Sub
Private Sub Cpr_Change()
    testFelter
End Sub
Private Sub UdlåntAf_Change()
    testFelter
End Sub
Private Sub MaskineNr_Change()
    testFelter
End Sub
Private Sub AntalController_Change()
    testFelter
End Sub
Private Sub CommandButton1_Click()
Dim dokRække
    dokRække = 1
   
Rem Ophæv beskyttelsen
    ActiveDocument.Unprotect
   
Rem indsæt felterne CelleNr, Navn, Cpr, MaskineNr, Antal controller & UdlåntAf
    ActiveDocument.FormFields("tekst1").Result = Me.CelleNr
    ActiveDocument.FormFields("tekst2").Result = Me.Navn
    ActiveDocument.FormFields("tekst3").Result = Me.Cpr
    ActiveDocument.FormFields("rulleliste3").Result = Me.MaskineNr
    ActiveDocument.FormFields("rulleliste2").Result = Me.AntalController
    ActiveDocument.FormFields("tekst4").Result = Me.UdlåntAf
   
Rem Indsæt spil-titler
    For f = 0 To ListBox1.ListCount - 1
        If ListBox1.Selected(f) = True Then
            With ActiveDocument.Tables(1)
                .Rows(dokRække).Select
                Selection.TypeText Text:=ListBox1.List(f)
                dokRække = dokRække + 1
            End With
        End If
    Next f
    ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True
   
    Unload UserForm1
End Sub
Private Sub CommandButton2_Click()
    Unload UserForm1
End Sub
Private Sub ListBox1_Change()
    If ListBox1.Selected(ListBox1.ListIndex) = True Then
        If antalUdlån < 2 Then
            antalUdlån = antalUdlån + 1
        Else
            MsgBox ("Der er nu udlånt 2 spil! - du må fravælge et, hvis du vil vælge et andet")
            ListBox1.Selected(ListBox1.ListIndex) = False
            antalUdlån = antalUdlån + 1
        End If
    Else
        If antalUdlån > 0 Then
            antalUdlån = antalUdlån - 1
        End If
    End If
End Sub
Private Sub UserForm_activate()
    findSti
    indlæsPS2spil
   
    Me.CommandButton1.Enabled = False
    Me.ListBox1.Enabled = False
    antalUdlån = 0
   
    For f = 1 To ActiveDocument.FormFields("rulleliste3").DropDown.ListEntries.Count
        Me.MaskineNr.AddItem f
    Next f
   
    For f = 1 To ActiveDocument.FormFields("rulleliste2").DropDown.ListEntries.Count
        Me.AntalController.AddItem f
    Next f
   
    Me.MaskineNr = ""
    Me.AntalController = ""
   
    Me.CelleNr.SetFocus
End Sub
Private Sub findSti()
    sti = ActiveDocument.AttachedTemplate.Path
    If Right(sti, 1) <> "\" Then
        sti = sti + "\"
    End If
End Sub
Private Sub indlæsPS2spil()
Dim titel As String
    Open sti + "ps2_spil.txt" For Input As #1
        While Not EOF(1)
            Input #1, titel
            Me.ListBox1.AddItem titel
        Wend
    Close #1
End Sub

Tak til supertekst for en afsindig fyldestgørende hjælp.

Jeg fik det som jeg gerne ville have det.
--
Janus

Selv tak..