Skrivning til Binær fil

Brug en Type-erklæring.

(OBS: Nedenstående er lavet i Excel-VBA, så det kan måske være nødvendigt med justeringer til VB)

'Lav et modul, copy'n'paste koden ind:

Option Explicit

'Data bliver gemt i en "Record" af denne type:
Type tKortData
  XKorLokal As Long
  YKorLokal As Long
  ZKorLokal As Long
  RelYKorLokal As Integer
  KortTextLokal As String * 12
End Type

Dim KortData As tKortData

Sub WriteRecord()
  Dim lFileNumber As Long
  Dim bCounter As Byte
  Const FilNavn As String = "C:\Temp\KortData.Bin" ' Ret sti & navn til :-)
 
  lFileNumber = FreeFile 'Returnerer ledigt filnummer.
 
  'Åben binær-filen for skrivning. Lås for andre.
  Open FilNavn For Binary Access Write Lock Write As lFileNumber
 
 
  'Hæld lidt testdata ind:
  For bCounter = 0 To 254
      With KortData
        .XKorLokal = 1000
        .YKorLokal = 2000
        .ZKorLokal = 3000
        .RelYKorLokal = bCounter
        .KortTextLokal = "Lokal12"
      End With
     
      'Skriv Record i filen
      Put #lFileNumber, , KortData
  Next bCounter
  'Luk filen
  Close lFileNumber
 
  'Rens Record. Evt. fejl giver så en forkert værdi ved genindlæsning.
  With KortData
      .XKorLokal = 0
      .YKorLokal = 0
      .ZKorLokal = 0
      .RelYKorLokal = 0
      .KortTextLokal = ""
  End With
 
  lFileNumber = FreeFile 'Returnerer ledigt filnummer
 
  'Åben binær-filen for læsning. Lås for andre.
  Open "C:\Temp\KortData.Bin" For Binary Access Read Lock Read As lFileNumber
 
  While Not EOF(lFileNumber)
      'Læs record fra filen
      Get #lFileNumber, , KortData
      'Vis hentet indhold
      With KortData
        MsgBox "Hentet" & vbNewLine & _
                "XKorLokal = " & .XKorLokal & vbNewLine & _
                "YKorLokal = " & .YKorLokal & vbNewLine & _
                "ZKorLokal = " & .ZKorLokal & vbNewLine & _
                "RelYKorLokal = " & .RelYKorLokal & vbNewLine & _
                "KortTextLokal = " & .KortTextLokal, _
                vbOKOnly, "Data gemt i filen:"
      End With
  Wend
  'Luk filen
  Close lFileNumber
End Sub

Det ser jo ud til at være det jeg leder efter. Har rygende travlt, men håber jeg får tid til at teste det lidt senere. Foreløbig tak.

Det virkede perfekt, og det sparer en del tid - så smid et svar.

Der er temmeligt meget data i nogle af de filer jeg bearbejder, og programmet har jo stadig den nye fil åben til skrivning en gang på linie. Ville det kunne spare yderligere tid at skrive alle linierne i et array, og så skrive filen en gang for alle til sidst??

Jensee

og der skulle stå pr. linie og ikke på linie...

Tak for respons, jeg er glad for at det kunne hjælpe dig :-)

Tidsbesparelse: ja, du vil kunne hente lidt tid, men da OS'et cacher data fra/til hd'ere tror jeg ikke at du vinder timer :-).
"Temmeligt meget data" er et lidt abstrakt begreb :-), for hvis du har så meget data at dit programmet skal bruge virtuel hukommelse (hd-plads) så ryger besparelsen lidt.