DateAdd - uden weekend

Et bud:

    Public Function WorkingDays(ByVal dDate As Date, ByVal lInterval As Long) As Date
        Dim x As Long ' Count of Working Days
        ''' Dim y As Long ' Count of Actual Days
        Dim dNewDate As Date ' The date being checked

        Dim dayStep As Integer
        If lInterval >= 0 Then
            dayStep = 1
        Else
            dayStep = -1
        End If

        dNewDate = dDate
        Do Until x = lInterval
            dNewDate = DateAdd("w", dayStep, dNewDate)
            If Not Weekday(dNewDate) = vbSunday And Not Weekday(dNewDate) = vbSaturday Then
                x = x + dayStep
            End If
        Loop
        WorkingDays = dNewDate
    End Function

Takker - det virker perfekt

Hmmm? Hvorfortager du så pointene selv?

Ja, det er ikke særligt befordrende for lysten til at hjælpe dig. :-(

-----

Men da jeg går ud fra, at du har gjort det ved en fejl, kommer her endnu et bud på en måde at beregne din dato (uden brug af loops):

Function AddArbejdsdage(startdato As Date, Arbejdsdage As Integer) As Date
    Dim beregnetDato As Date
    Dim wd As Integer
    Dim corrDays As Integer
   
    beregnetDato = DateAdd("d", Int(Arbejdsdage / 5) * 7 + (Arbejdsdage Mod 5), startdato)
   
    ' Beregn evt. nødvendig korrektion for weekenden...
    wd = Weekday(beregnetDato, vbSaturday)
    If wd > 2 Then
        corrDays = 0
    ElseIf Arbejdsdage > 0 Then
        corrDays = 3 - wd
    Else
        corrDays = -wd
    End If
   
    'Korriger evt. for weekend...
    If corrDays <> 0 Then
        beregnetDato = DateAdd("d", corrDays, beregnetDato)
    End If
   
    'Returnere den beregnede dato...
    AddArbejdsdage = beregnetDato

End Function

PS: Jeg skal ikke have point, da nielle jo kom først med en funktion der virker. Ham bør du derimod straks belønne med de udsatte 60 point. Det er virkelig kontraproduktivt (= du kan få resten af brugerne på nakken og få svært ved at få hjælp næste gang), ikke at give de lovede point til dem som laver arbejdet, og kommer med en løsning på det stillede problem.