Problem: Nul returneres istedet for blank

Med hjaelp fra bl.a. Bak og Oyejo har jeg lavet nedenstaaende macro der henter data i lukkede workbooks i en mappe. (Tak for det Bak og oyejo).
Jeg har dog noget jeg gerne vil have rettet, hvis cellevaerdien er blank (Intet celleindhold) i mine ark, saa returneres der et nul, er det muligt at lave macroen om saa der returneres en blank celle eller alternativt "N/A" for Not available.



Sub GetValuesFromClosedFiles()
  Dim FS As FileSearch
  Dim FilePath As String
  Dim i As Integer, j As Integer, n As Integer, c As Integer
  Dim v As Variant
  Dim Cells2Get()
  Dim sheetNameEnd()
  Dim sheet As String
 
 
  Const Filespec = "*.xls"  'udfyldes af bruger Filtype
  'udfyldes af bruger Startfolder
  FilePath = "C:\test\"
  sheetNameEnd() = Array("0", "i", "ii", "iii", "iv")
 
  'udfyldes af bruger Celler, der skal hentes,
  'NB! EN LINJE(ARRAY) FOR HVERT ARK
  Cells2Get = Array(Array("B10", "C10"), _
                    Array("B11", "C11", "D11"), _
                    Array("B12", "C12"), _
                    Array("B13", "C13"), _
                    Array("B14", "C14"))
 
  Application.ScreenUpdating = False
 
  Set FS = Application.FileSearch
  With FS
    .LookIn = FilePath
    .Filename = Filespec
    .Execute
    If .FoundFiles.Count = 0 Then
      MsgBox ("Ingen filer fundet")
      Exit Sub
    End If
   
    For i = 1 To .FoundFiles.Count
      c = 0
      v = Split(.FoundFiles(i), Application.PathSeparator)
      FilePath = Left(.FoundFiles(i), InStrRev(.FoundFiles(i), _
                                      Application.PathSeparator))
      ActiveCell.Offset(i, 0) = FilePath & v(UBound(v))
     
      For n = 0 To UBound(sheetNameEnd)
        sheet = "part" & sheetNameEnd(n)
        For j = 0 To UBound(Cells2Get(n), 1)
          c = c + 1
          ActiveCell.Offset(i, c) = GetValue(FilePath, v(UBound(v)), sheet, Cells2Get(n)(j))
        Next
      Next
    Next
  End With
 
  Application.ScreenUpdating = False
 
End Sub



Private Function GetValue(path, file, sheet, range_ref)
Dim arg As String
arg = "'" & path & "[" & file & "]" & sheet & "'!" & Range(range_ref).Range("A1").Address(, , xlR1C1)
GetValue = ExecuteExcel4Macro(arg)
End Function