Padding is invalid and cannot be removed

Smider også lige koden til kryptering:

Public Sub Encrypt(ByVal name As String, ByVal data As String)
            Dim loc As String = String.Format("{0}\{1}.txt", Locations.SafeItemsDirectory, name)
            Dim stream As FileStream = File.Open(loc, FileMode.OpenOrCreate)

            Dim alg As Rijndael = Rijndael.Create
            alg.IV = _iv
            alg.Key = _password

            Dim crypto As New CryptoStream(Stream, alg.CreateEncryptor(), CryptoStreamMode.Write)
            Dim writer As New StreamWriter(crypto)

            writer.WriteLine(data)

            writer.Close()
            crypto.Close()
            stream.Close()
        End Sub

jeg er meget skeptisk overfor brug af Writer og Reader med binary data

kan du ikke bruge raa stream IO ?

Hvordan mener du? Og hvorfor?

Jeg er åben overfor forslag :)

Dim writer As New StreamWriter(crypto)
writer.WriteLine(data)

->

crypto.Write(Encoding.Default.GetBytes(data))

og

Dim reader As New StreamReader(crypto)
Return reader.ReadToEnd

->

crypto.Read(b, 0, n)
return Encoding.Default.ToString(b, 0, n)

hvor b er et passende stort byte array

det sidste skal vaere:

n = crypto.Read(b, 0, b.Length)
return Encoding.Default.ToString(b, 0, n)

Okay, men jeg har ingen anelse om hvad passende stort er..

du bruger filens stoerelse !

Nå ja... Nu er det vist også på tide jeg holder for i dag :)

Return Encoding.Default.ToString(b, 0, n) forstår jeg ikke lige helt... Så vidt jeg kan se tager ToString ikke i mod sådan et sæt parametre.

En anden ting; det skal vel være:
n = crypto.Read(b, 0, b.Length -1) ?

Return Encoding.Default.GetString(b, 0, n)

hvorfor vil du traekke 1 fra - C# er ikke C

Length giver vel 1 for meget når arrayet starter ved 0?

Anyways, jeg får "Padding is invalid and can not be removed." ved:
n = crypto.Read(b, 0, b.Length)

nej

arrayet indeholder b.Length elementer med index fra 0 til b.Length-1

men det argument er antal elementer ikke index paa sidste element

jeg bliver vist noedt til at lave et simpelt eksempel

:-)

det her virker:

Imports System
Imports System.IO
Imports System.Text
Imports System.Security.Cryptography

Public Class MainClass
    Public Shared Sub Save(data As String, key As String, fnm As String)
        Dim stm As Stream = New FileStream(fnm, FileMode.Create, FileAccess.Write)
        Dim alg As Rijndael = Rijndael.Create
        alg.IV = New Byte() { 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15 }
        alg.Key = Encoding.Default.GetBytes(key)
        Dim crypto As New CryptoStream(stm, alg.CreateEncryptor(), CryptoStreamMode.Write)
        Dim b As Byte() = Encoding.Default.GetBytes(data)
        crypto.Write(b, 0, b.Length)
        crypto.Close()
    End Sub
    Public Shared Function Load(fnm As String, key As String) As String
        Dim n As Integer = (New FileInfo(fnm)).Length
        Dim stm As Stream = New FileStream(fnm, FileMode.Open, FileAccess.Read)
        Dim alg As Rijndael = Rijndael.Create
        alg.IV = New Byte() { 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15 }
        alg.Key = Encoding.Default.GetBytes(key)
        Dim crypto As New CryptoStream(stm, alg.CreateDecryptor(), CryptoStreamMode.Read)
        Dim b(n) As Byte
        n = crypto.Read(b, 0, b.Length)
        crypto.Close()
        return Encoding.Default.GetString(b, 0, n)
    End Function
    Public Shared Sub Main(ByVal args As String())
        Save("Dette er en lille test", "012345670123456701234567", "C:\cryp.dat")
        Console.WriteLine(Load("C:\cryp.dat", "012345670123456701234567"))
    End Sub
End Class

Tak for det :) Smid et svar.

OK

du har ogsaa faaet det til at virke ?

Hahahha... Ja, ellers havde jeg sagt noget :)

Jeg undrer mig dog over at det andet ikke ville virke, men nu er kryptografi og streams heller ikke lige noget jeg er super god til.

Tak for hjælpen.