Hvis formel + lopslag

hvad vil du finde/slå op ?

=LOPSLAG("det du vil slå op";A1:AA400;2;FALSK)

Den finder værdien i kolonne til højre for den værdi du vil slå op...

=LOPSLAG("????";Ark2!A1:AA400;2;FALSK)

Jeg har en tekst og et tal på det ene faneblad og en tekst og et tal på anden. De står dog ikke iorden. Jeg vil kunne søge på teksten og når den stemmer, så skal den søge vidre på talet og finde mit svar. men kun inden for de rækker, hvor teksten findes.

VIS ET EKSEMBEL

Hvis(A4=faneblad2A1:A400;+lopslag(A10=faneblad2C;E;2;falsk);"")

Prøv denne. er stadig lidt i tvivl om hvad du mener

skift Ark2 ud med dit navn  husk tast ! efter navnet

=HVIS(ER.TEKST(LOPSLAG(A4;Ark2!A1:A400;1;FALSK));LOPSLAG(A10;Ark2!A1:E400;2;FALSK);"")

Det er desvære ikke nok med at den henter et tal, hvis der er tekst. Teksten skal være ens fra det ene ark til det andet.

Altså hvis der står Jysk i ar1, så skal den først kunne finde Jysk i ark2 og hvis den er sand, så lave et opslag. Men kun inden for de rækker der står jysk i.

Håber det hjælper

Et skud i tågen:
Med en lille omskrivning af excelents forslag, kunne denne måske virke.
=HVIS(ER.fejl(LOPSLAG(A4;Ark2!A1:A400;1;FALSK));"";LOPSLAG(A4;Ark1!A1:B400;2;FALSK))

Desvære. det virker til at hente den først række med tal. Men når jeg køre vidre ud og den skal finde en anden tekst på arket, så laver den stadigvæk lopslag på de gamle tal. Den fortsætter ikke.

For mig lyer det som om at du skal bruge opslagsværdien i det første udtryk til at lave endnu et opslag i arket. Er det korrekt ?
I så fald prøv denne =HVIS(ER.fejl(LOPSLAG(A4;Ark2!A1:A400;1;FALSK));"";LOPSLAG((LOPSLAG(A4;Ark2!A1:A400;1;FALSK));Ark1!A1:B400;2;FALSK))

problemet er nok, at lopslag kun kikker på den først forekomne opslags værdi
og hvis det er jysk og de forekommer flere gange så...

Det er rigtigt. Den har fundet jysk og derfor bruger den bare den først kommene opslagsværdi.

Ja excelent, jeg tror du har ret, da japers skriver "inden for de rækker", men lad os se om der kommer en lidt bedre forklaring på hvad der ønskes.

Den virker ikke med de to lopslag. For her kommer jeg ikke ind og søger på værdien på noget tidspunkt kun teksten

ok mrjh.Jeg prøver at forklare mig lidt bedre. Det går hvis ikke så godt for mig. Formlen skal starte med at finde jysk i ark 1 og 2. Hvis det er "OK", så skal det søge på en tal værdi. Problemet er at i ark 2 står der både jysk og fyn. Så det burde ikke være noget problem, men talværdierne er ens
               
Ark 2                Værdien den skal hentes

Tekst  Tal
Jysk    1                100
Jysk    2                200
Jysk    3                300

Fyn    1                500
Fyn    2                600
Fyn    3                700

Så når den har sagt ok til fyn, så henter den bare 1. Hvilken så bliver 100, men som skal være 500.

Håber det hjælper, ellers prøver jeg bare igen

Ahaaa, begge værdier skal være opfyldt, i så fald endnu et bud:
Dine opslagsværdier i D1 og E1
{=INDEKS(A1:C400;SAMMENLIGN(D1&E1;A1:A400&B1:B400;0);3)}
Afslut formel med ctrl+shift+enter
Formlen finder værdien i kolonne C, og skal selvfølgelig rettes til dine værdier

Hov, fik ikke set dit sidste indlæg før jeg svarede. Prøv at indsætte din formel her på siden.

HVIS(ER.FEJL(+LOPSLAG(Udkreditering!O$7;'Beholdninger DI'!$A:$G;1;FALSK));"";+LOPSLAG(+LOPSLAG(Udkreditering!O$7;'Beholdninger DI'!A:G;1;FALSK);'Beholdninger DI'!A:G;6;FALSK))

Her er min formel.

Jan

Jeg takker mange gange. Jeg brugte din Indeksformel og den virker. Nu kommer den bare med en eller anden værdi fejl. Men inden i formlen der har den fundet det rigtige tal

Fint, ellers ret den til med denne, som tager højde for fejlværdierne.

=HVIS(ER.FEJL(INDEKS(A33:A37;SAMMENLIGN(G34;A33:A37;0);1));"";HVIS(ER.FEJL(INDEKS(A33:C37;SAMMENLIGN(G34&H34;A33:A37&B33:B37;0);3));"";INDEKS(A33:C37;SAMMENLIGN(G34&H34;A33:A37&B33:B37;0);3)))

Hov, det går rigtig godt idag :-)

Tilret med denne:

=HVIS(ER.FEJL(INDEKS(A1:A400;SAMMENLIGN(D1;A1:A400;0);1));"";HVIS(ER.FEJL(INDEKS(A1:C400;SAMMENLIGN(D1&E1;A1:A400&B1:B400;0);3));"";INDEKS(A1:C400;SAMMENLIGN(D1&E1;A1:A400&B1:B400;0);3)))

Du tog selv P. Fair nok, men det ville være rart at vide hvorfor du ikke kunne bruge ovennævnte løsning. Bare til en anden gang. :-)

Det virker også. Men jeg er ny og ved ikke lige hvordan jeg skal give points videre eller hvordan jeg skal kontakte dig. Skal jeg oprette et nyt spørsmål ??

Ok, det er forståeligt. Jeg troede bare at du måske havde fundet en anden løsning, og den havde jeg da været interesseret i i givet fald. Du er nødt til at oprette et nyt spørgsmål (overskrift f.eks: Point til mrjh), som jeg så svarer på og først derefter kan du afgive point ved at markere mit navn i venstre side og accepterer c",)

Ok, det opretter jeg

Så er det klaret