Oprette brugere i AD og oprette websites via scripts

Jeg har et script til w2003 hvor du kan oprette websites, men hvorfor vil du oprette brugere dertil også...

Hej ttopholm
er det den man bruges i w2003 web
for jeg er også ude efter en.
har søgt efter en men har opgivet

mvh

mvhansen

Jep det er en til at tilføje websites til IIS 6

Må man spørge om hvor man kan finde sådanne en

hej john2004

du må undskylde at jeg bryder ind i dit spørsmål


mvh

mvhansen

' Make connections to WMI, to the IIS namespace on MyMachine, and to the Web service.
set locatorObj = CreateObject("WbemScripting.SWbemLocator")
set providerObj = locatorObj.ConnectServer("MyMachine", "root/MicrosoftIISv2")
set serviceObj = providerObj.Get("IIsWebService='W3SVC'")

' Build binding object, which is a required parameter of the CreateNewSite method.
' Use the SpawnInstance WMI method since we are creating a new instance of an object.
Bindings = Array(0)
Set Bindings(0) = providerObj.get("ServerBinding").SpawnInstance_()
Bindings(0).IP = ""
Bindings(0).Port = "8383"
Bindings(0).Hostname = ""

' Create the new Web site using the CreateNewSite method of the IIsWebService object.
Dim strSiteObjPath
strSiteObjPath = serviceObj.CreateNewSite("MyNewSite", Bindings, "C:\Inetpub\Wwwroot")
If Err Then
WScript.Echo "*** Error Creating Site: " & Hex(Err.Number) & ": " & Err.Description & " ***"
WScript.Quit(1)
End If

' strSiteObjPath is in the format of IIsWebServer='W3SVC/1180970907'
' To parse out the absolute path, W3SVC/1180970907, use the SWbemObjectPath WMI object.
Set objPath = CreateObject("WbemScripting.SWbemObjectPath")
objPath.Path = strSiteObjPath
strSitePath = objPath.Keys.Item("")

' Set some properties on the root virtual directory which was created by CreateNewSite.
Set vdirObj = providerObj.Get("IIsWebVirtualDirSetting='" & strSitePath & "/ROOT'")
vdirObj.AuthFlags = 5 ' AuthNTLM + AuthAnonymous
vdirObj.EnableDefaultDoc = True
vdirObj.DirBrowseFlags = &H4000003E ' date, time, size, extension, longdate
vdirObj.AccessFlags = 513 ' read, script
vdirObj.AppFriendlyName = "Root Application"

' Save the new settings to the metabase
vdirObj.Put_()

' CreateNewSite does not start the server, so start it now.
Set serverObj = providerObj.Get(strSiteObjPath)
serverObj.Start

WScript.Echo "A New site called MyNewSite was created with the path and unique site identification number of " & strSitePath

den opretter et site.. der hedder MyNewSite.. og stien er C:\Inetpub\wwwroot
hostname er sat til ingenting.. port er sat til 8383

Tak ttopholm

skal den gemmes som asp eller html
det er nok asp.
jeg har også været ude efter et script der kan oprette mail adresser, når man har oprettet et domane, ligsom på et webhotel, kan man indenfor domanenavnet oprette mail adresser.

jeg opretter et spørsmål når jeg lige får tid i iis
jeg arbejder lige i tiden i excel
så jeg har ikke tid til at kigge på det nu

undskyld john2004

mvh

mvhansen

i en vbs fil... du skal omskrive den lidt til asp

Hej ttopholm.
Jeg takker for hjælpen. Smider du lige et svar?

Det var så lidt