Hente htmlside som txt-fil via bat-fil. Med login

<ole>

Hvordan logger du ind? Via en .htaccess-login eller en 'hjemmestrikket' login?

/mvh
</bole>

Jeg får et vindue hvor jeg i den bedste windows stil kan logge ind. Har mulighed for at "Husk adgangskoden" . Hvis du prøver adr. www.statisten.dk/dbdump kan du se hvordan :-)

Hmmm ... så ville jeg nok vælge at bruge enten wininet- eller winsock-kontrollen, men om du kan det fra en bat-fil, ved jeg ikke(?)

Det behøver ikke at være en .bat fil. Sålænge den kan aktiveres med et tryk eller med planlægning er det fint. En .vbs fil evt.

En .vbs-fil:

Dim sUrl, sPath, sUser, sPass, oHttp, oStream

sUrl = "http://www.eksperten.dk"
sPath = "C:/copy_of_eksperten.html"
sUser = "myUserName"
sPass = "myPassWord"

Set oHttp = CreateObject("MSXML2.XMLHTTP.3.0")
oHttp.Open "GET", sUrl, False, sUser, sPass
oHttp.Send

Set oStream = CreateObject("ADODB.Stream")
oStream.Type = 1
oStream.Open
oStream.Write oHttp.responseBody
oStream.SaveToFile sPath, 2
oStream.Close

Set oHttp = Nothing
Set oStream = Nothing

Det virker sgu!!!
Det eneste er at den henter det i html formatet. Dvs at når man kalder denne side manuelt og logger sig ind ser man siden oversat af IE, men hvis man ser kilden oplever man en tab sepereret fil og den gemmer jeg så.
Eks på tab seperet fil:
felt1  felt2  felt3 \n
værdi  værdi  værdi \n  osv....

jeg tror ikke den fortolker linieskiftne korrekt?

Den gemmer, hvad der står i koden - hvilket er det samme, du ser, når du kikker i kildekoden i IE. Dog kan der netop være forskelle omkring linjeskift (forskellige platforme anvender forskellige linjeskift). Se bort fra dette ... det kan fikses.
Jeg vil gerne vide, om du mener, der skulle være andre forskelle - og i så fald, hvilke  :)

Du kan evt. prøve dette hurtige, omend knap så skønne, fix af linjeskiftene:

Dim sUrl, sPath, sUser, sPass, oHttp, oStream, oFso, oFile, sStr

sUrl = "http://www.eksperten.dk"
sPath = "C:/copy_of_eksperten.html"
sUser = "myUserName"
sPass = "myPassWord"

Set oHttp = CreateObject("MSXML2.XMLHTTP.3.0")
oHttp.Open "GET", sUrl, False, sUser, sPass
oHttp.Send

Set oStream = CreateObject("ADODB.Stream")
oStream.Type = 1
oStream.Open
oStream.Write oHttp.responseBody
oStream.SaveToFile sPath, 2
oStream.Close

Set oFso = CreateObject("Scripting.FileSystemObject")
Set oFile = oFso.OpenTextFile(sPath, 1)
sStr = oFile.ReadAll()
oFile.Close

sStr = Replace(sStr, vbLf, vbCrLf)

Set oFile = oFso.OpenTextFile(sPath, 2)
oFile.Write sStr
oFile.Close

Set oHttp = Nothing
Set oStream = Nothing
Set oFso = Nothing
Set oFile = Nothing

Er lige kommet fra langt møde!

Det virker lige som det skal...
Teksten bliver nu præsenteret i perfekt tab sepereret format :-)
Jeg takker mange gange og vil godt sige at eksperten er uvurderligt

Jamen, det lyder fint ... og du kan naturligvis godt gemme filen i et andet format - f.eks. som en .txt-fil  :)

har jeg gjort :-)

- fjong ... og tak for points  ;o)