Kopier række i samme tabel

I VBA kan du bruge flg.:

DoCmd.RunCommand acCmdSelectRecord
DoCmd.RunCommand acCmdCopy
DoCmd.GoToRecord acForm, "Form1", acNewRec
DoCmd.RunCommand acCmdSelectRecord
DoCmd.RunCommand acCmdPaste

som kopierer fiormularens aktuelle post og indsætter den som en ny post. Et evt. id (autonummereringsfelt) PK, vil blive indsat som et fortløbende nr.

Man behøver ikke angive kolonnerne i en insert, så du kan sige:

Insert Into My_Table
Select *
From My_Table
where ID=2

- det samme som du skrev, men med en stjerne mindre. Men får for du id=2 kopieret med og ikke et nyt id=4 som du ønsker.

Der er ingen mulighed for SELECT * EXCEPT ID FROM ..., så du bliver nok nødt til at lave noget kode der indlæser kolonnerne og genererer din insert-sql ud fra det.

Hvis ikke du har frygteligt mange tabeller, er det vel nemmere at lave en insert for hver, såsom:

INSERT INTO My_Table (NAVN, MAIL)
SELECT NAVN, MAIL
FROM My_Table
WHERE ID = @idToCopy

Der er vel auto-incement på din ID...

En VBA funktion som den følgende burde kunne klare opgaven:

Public Function DuplicateRow(Table As String, RowID As Long) As Integer
On Error GoTo DupRowError

Dim rsFrom As DAO.Recordset
Dim rsTo As DAO.Recordset
DuplicateRow = False

Set rsFrom = CurrentDb.OpenRecordset("SELECT * FROM " & Table & " WHERE ID =" & RowID)
Set rsTo = CurrentDb.OpenRecordset(Table)
rsFrom.MoveFirst
If rsFrom.RecordCount > 0 Then
    rsTo.AddNew
    ' Gennemløb alle felter i tabellen, og hvis feltet i den nye row
    ' er opdaterbart og ikke et autonum-felt
    ' så kopier feltet til den nye record (aka. row).
    For Each Field In rsFrom.Fields
        If (rsTo.Fields(Field.Name).Attributes And dbUpdatableField) = dbUpdatableField And _
                (rsTo.Fields(Field.Name).Attributes And dbAutoIncrField) <> dbAutoIncrField Then
            rsTo.Fields(Field.Name).Value = rsFrom.Fields(Field.Name).Value
        End If
    Next
    rsTo.Update
    DuplicateRow = True
End If
rsFrom.Close
rsTo.Close
Exit Function
DupRowError:
    MsgBox Error$, vbExclamation + vbOKCancel, "Fejl under duplikering af row"
   
End Function


Den kaldes sådan (eksempel):

Dim OK as Integer
OK = DuplicateRow("tabelnavn", 5)
If OK Then
  Msgbox("Den ønskede row er blevet duplikeret")
End If

PS. DAO prefixet i dimensioneringen af Recordset er normalt ikke nødvendig, men af en eller anden grund kræver min Access 2003 dette...

Lukker den.

Kan jeg få en begrundelse for din afvisning af mit forslag? Virkede det ikke hos dig? Hos mig gjorde det...